Allocatable argument 'x' is not allocated

Describe the issue
Command gnumake -f Makefile.manual FYPPFLAGS=-DMAXRANK=4 test on Windows with GCC-11.1.0 x64, ends with

./test_linspace
 Made it through first round of tests
At line 111 of file test_linspace.f90
Fortran runtime error: Allocatable argument 'x' is not allocated

With GCC-10.3.0 x64, it works:

./test_linspace
 Made it through first round of tests
./test_logspace
gnumake[2]: Leaving directory 'C:/fortran/stdlib/src/tests/math'
gnumake[1]: Leaving directory 'C:/fortran/stdlib/src/tests'

All tests passed.

[jvdp1]

thank you @brocolis for reporting this issue. I can reproduce it on my Fedora computer (gcc 11.1.1). I will have a check

[jvdp1]

the issue happens at the line 109 of test_linspace.f90.

Issue: a negative argument (-15) is provided to the function linspace. In such a case, it is assumed that the result would be an array of size 0 (see the code here). However, with gcc11, the array remains dealloacted, which triggers the runtine error when evaluating size(x) at the following line.

Is it an issue with the code (violating the standard) or with gfortran?

Ping: @ejovo13 @certik @milancurcic @ivan-pi @awvwgk

[ejovo13]

Thank you for reporting this.

I'm on vacation camping but I will be back on the grid by this weekend. Feel free to leave any more information and I will investigate.

I know that other versions of gcc/gfortran were working. For example, on arch gcc version 11, the negative index was properly allocated to a size 0 array.

[14NGiestas]

this answer STD 2018, 12.6.2.2, pg4 states that:

The characteristics (12.3.3) of the function result are those of the result variable. On completion of execution of the function, the value returned is that of its result variable.

So if the result variable is unallocated, the return value will follow and since the argument to size must not be an unallocated allocatable variable, this leads to a error, so I believe gcc11 is correct.

A quick fix would simply force the length 0 when n <= 0

-      if(n <= 0) return ! If passed length is less than or equal to 0, return an empty (allocated with length 0) array
+     ! If passed length is less than or equal to 0, return an empty (allocated with length 0) array
+     if (n <= 0) then
+          allocate(res(0))
+          return
+     end if

EDIT: Ok... just checked that res isn't allocatable, this would imply that arrays in stack with size zero are not being allocated or something similar.

[14NGiestas]

I made a gist with a attempt to isolate the issue but couldn't find anything odd with the outputs (maybe a issue with 11.1.1) or any flags?
EDIT: Actually the only odd thing is that dummy(0) and dummy(-100) one is allocated the other isn't and that's a problem

[jvdp1]

I believe that the main issue is that the result of the function is not allocatable, but is declared as, e.g., `real(dp) :: res(n)`. Therefore, it is different than `allocate(res(-15))` Le ven. 23 juil. 2021 à 14:01, Ian Giestas Pauli ***@***.***> a écrit :

…

I made a gist with a attempt to isolate the issue <https://gist.github.com/14NGiestas/78150b1feed3b5f54e9b68b698e340ad> but couldn't find anything odd with the outputs (maybe a issue with 11.1.1) or any flags? — You are receiving this because you commented. Reply to this email directly, view it on GitHub <#472 (comment)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/AD5RO7FUAHB5MUJO5B62U43TZFK2XANCNFSM5AZCX77Q> .

[14NGiestas]

I believe edits aren't being sent over e-mail (which makes sense, anyway):

Stack allocated variables is somewhat unreliable in this case, runtime negative indexes leaves the return unallocated, compile time negative indexes allocate the return with zero size.

program main
    implicit none
    real, allocatable :: x(:)

    x = dummy1()
    print*, allocated(x) ! T
    print*, size(x)      ! 0

    x = dummy2(100)
    print*, allocated(x) ! F
    print*, size(x)      ! 0

    x = dummy2(0)
    print*, allocated(x) ! T
    print*, size(x)      ! 0
contains

    function dummy1() result(res)
        real :: res(-100)
    end function

    function dummy2(n) result(res)
        integer, intent(in) :: n
        real :: res(-n)
    end function
end program

EDIT: spelling

[jvdp1]

Thank you. Just got an idea: What about: `real(dp) :: res( merge(n, 0, n > 0))` instead of `real(dp) :: res(n)` ?

[14NGiestas]

Neat! That probably solves the issue, and require minimum changes.

program main
    implicit none
    real, allocatable :: x(:)

    x = dummy1()
    print*, allocated(x) ! T
    print*, size(x)      ! 0

    x = dummy2(100)
    print*, allocated(x) ! T
    print*, size(x)      ! 100

    x = dummy2(-100)
    print*, allocated(x) ! T
    print*, size(x)      ! 0

    x = dummy2(0)
    print*, allocated(x) ! T
    print*, size(x)      ! 0
contains

    function dummy1() result(res)
        real :: res(-100)
    end function

    function dummy2(n) result(res)
        integer, intent(in) :: n
        real :: res(merge(n, 0, n > 0))
    end function
end program

[jvdp1]

Thank you for testing it. Would you like to submit a PR with this change, if it works, please? It would be helpful. Le ven. 23 juil. 2021 à 15:54, Ian Giestas Pauli ***@***.***> a écrit :

…

Neat! That probably solves the issue, and require minimum changes. program main implicit none real, allocatable :: x(:) x = dummy1() print*, allocated(x) ! T print*, size(x) ! 0 x = dummy2(100) print*, allocated(x) ! T print*, size(x) ! 100 x = dummy2(-100) print*, allocated(x) ! T print*, size(x) ! 0 x = dummy2(0) print*, allocated(x) ! T print*, size(x) ! 0contains function dummy1() result(res) real :: res(-100) end function function dummy2(n) result(res) integer, intent(in) :: n real :: res(merge(n, 0, n > 0)) end functionend program — You are receiving this because you commented. Reply to this email directly, view it on GitHub <#472 (comment)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/AD5RO7D42IWSCVQSB5EZJS3TZFYBHANCNFSM5AZCX77Q> .