Merge pull request #1174 from Malabarba/master

Define command to run -main

Author: bbatsov

CHANGELOG.md

@@ -2,6 +2,7 @@
 
 ## master (unreleased)
 
+* [#1174](https://github.com/clojure-emacs/cider/pull/1174): New command `cider-run`, runs the project's `-main` function.
 * [#1164](https://github.com/clojure-emacs/cider/pull/1164): Fix an error in `cider-browse-ns--doc-at-point`.
 * [#1149](https://github.com/clojure-emacs/cider/pull/1149): [Two new ways](https://github.com/clojure-emacs/cider#cider-debug) to debug code, the `#break` and `#dbg` reader macros.
 * [#1165](https://github.com/clojure-emacs/cider/pull/1165): Extract `cider-set-relevant-connection` from `cider-switch-to-relevant-repl-buffer`.

cider-interaction.el

@@ -2164,6 +2164,35 @@ restart the server."
           (cider-jack-in prompt-project))
       (error "Can't restart CIDER for unknown project"))))
 
+(defvar cider--namespace-history nil
+  "History of user input for namespace prompts.")
+
+(defun cider--var-namespace (var)
+  "Return the namespace of VAR.
+VAR is a fully qualified Clojure variable name as a string."
+  (replace-regexp-in-string "\\(?:#'\\)?\\(.*\\)/.*" "\\1" var))
+
+(defun cider-run (&optional function)
+  "Run -main or FUNCTION, prompting for its namespace if necessary.
+With a prefix argument, prompt for function to run instead of -main."
+  (interactive (list (when current-prefix-arg (read-string "Function name: "))))
+  (let ((name (or function "-main")))
+    (-when-let (response (nrepl-send-sync-request
+                          (list "op" "ns-list-vars-by-name" "name" name)))
+      (-if-let (vars (split-string (substring (nrepl-dict-get response "var-list") 1 -1)))
+          (cider-interactive-eval
+           (if (= (length vars) 1)
+               (concat "(" (car vars) ")")
+             (let* ((completions (mapcar #'cider--var-namespace vars))
+                    (def (or (car cider--namespace-history)
+                             (car completions))))
+               (format "(#'%s/%s)"
+                       (completing-read (format "Namespace (%s): " def)
+                                        completions nil t nil
+                                        'cider--namespace-history def)
+                       name))))
+        (user-error "No %s var defined in any namespace" name)))))
+
 (provide 'cider-interaction)
 
 ;;; cider-interaction.el ends here

test/cider-tests.el

@@ -178,6 +178,14 @@
                     (nrepl-connection-buffers)))
      (should (equal (buffer-name b) (nrepl-current-connection-buffer))))))
 
+(ert-deftest test-cider--var-namespace ()
+  (should (string= (cider--var-namespace "#'a/var-two") "a"))
+  (should (string= (cider--var-namespace "#'a-two/var") "a-two"))
+  (should (string= (cider--var-namespace "#'a.two-three.b/var-c") "a.two-three.b"))
+  (should (string= (cider--var-namespace "a/var-two") "a"))
+  (should (string= (cider--var-namespace "a-two/var") "a-two"))
+  (should (string= (cider--var-namespace "a.two-three.b/var-c") "a.two-three.b")))
+
 
 ;;; response handling
 (ert-deftest test-cider-dbind-response ()