CP-45921: Use dnf as package manager for XS9

Given XS9 has updated to dnf and no yum is available,
xapi will choose package manager basing on following
- If dnf exists, use dnf
- otherwise, fallback to yum
xapi just presume dnf or yum is available in the system.

Because xapi decides to use dnf or yum according to the running
environment, this commit is compatible with yum/xs8 and dnf/xs9

Signed-off-by: Lin Liu <[email protected]>

Author: liulinC

ocaml/tests/suite_alcotest.ml

@@ -71,4 +71,5 @@ let () =
     @ Test_session.tests
     @ Test_xapi_cmd_result.tests
     @ Test_extauth_plugin_ADwinbind.tests
+    @ Test_pkg_mgr.tests
     )

ocaml/tests/test_pkg_mgr.ml

@@ -0,0 +1,42 @@
+open Pkg_mgr
+
+let test_default_to_dnf =
+  (* mock dnf binary to /bin/sh, to ensure exists and decouple dnf dependencies*)
+  Xapi_globs.dnf_cmd := "/bin/sh" ;
+  let check exp () =
+    let ac = Pkg_mgr.pmgr_cmd () in
+    let msg = Printf.sprintf "exp: %s <-> got: %s" exp ac in
+    Alcotest.(check string) msg exp ac
+  in
+  [
+    ( Printf.sprintf "unit -> %s" !Xapi_globs.dnf_cmd
+    , `Quick
+    , check !Xapi_globs.dnf_cmd
+    )
+  ]
+
+let test_add_sub_cmd =
+  Xapi_globs.dnf_cmd := "/bin/sh" ;
+  let params = ["--disablerepo=*"; "--enablerepo=test"] in
+  let str_parms = String.concat " " params in
+  let check inp exp () =
+    let ac = add_sub_cmd inp params in
+    let str_ac = String.concat " " ac in
+    let msg =
+      Printf.sprintf "%s %s -> %s" (dnf_sub_cmd_to_string inp) str_parms str_ac
+    in
+    Alcotest.(check string) msg exp str_ac
+  in
+  [
+    (Reposync, ["reposync"] @ params)
+  ; (Repoconfig, ["config-manager"] @ params)
+  ; (Repoquery, ["repoquery"] @ params)
+  ]
+  |> List.map (fun (x, y) -> (x, String.concat " " y))
+  |> List.map (fun (inp, exp) -> ("<omit inp>", `Quick, check inp exp))
+
+let tests =
+  [
+    ("test_use_dnf_as_defualt", test_default_to_dnf)
+  ; ("test_add_sub_cmd", test_add_sub_cmd)
+  ]

ocaml/xapi/pkg_mgr.ml

@@ -0,0 +1,58 @@
+type t = Yum | Dnf
+
+type sub_cmd = Reposync | Repoconfig | Repoquery
+
+(* Cache current package manager, so no need to check every time*)
+let pmgr = ref None
+
+let active () =
+  match !pmgr with
+  | None -> (
+    match Sys.file_exists !Xapi_globs.dnf_cmd with
+    | true ->
+        pmgr := Some Dnf ;
+        Dnf
+    | false ->
+        pmgr := Some Yum ;
+        Yum
+  )
+  | Some mgr' ->
+      mgr'
+
+let dnf_sub_cmd_to_string = function
+  | Reposync ->
+      "reposync"
+  | Repoconfig ->
+      "config-manager"
+  | Repoquery ->
+      "repoquery"
+
+let pmgr_cmd () =
+  match active () with Dnf -> !Xapi_globs.dnf_cmd | Yum -> !Xapi_globs.yum_cmd
+
+let reposync_cmd () =
+  match active () with
+  | Dnf ->
+      !Xapi_globs.dnf_cmd
+  | Yum ->
+      !Xapi_globs.reposync_cmd
+
+let repoquery_cmd () =
+  match active () with
+  | Dnf ->
+      !Xapi_globs.dnf_cmd
+  | Yum ->
+      !Xapi_globs.repoquery_cmd
+
+let repoconfig_cmd () =
+  match active () with
+  | Dnf ->
+      !Xapi_globs.dnf_cmd
+  | Yum ->
+      !Xapi_globs.yum_config_manager_cmd
+
+let plugins () = match active () with Dnf -> [] | Yum -> ["--plugins"]
+
+let add_sub_cmd sub_cmd params =
+  (match active () with Dnf -> [dnf_sub_cmd_to_string sub_cmd] | Yum -> [])
+  @ params

ocaml/xapi/repository.ml

@@ -128,9 +128,11 @@ let sync ~__context ~self ~token ~token_id =
     write_initial_yum_config () ;
     clean_yum_cache repo_name ;
     (* Remove imported YUM repository GPG key *)
-    Xapi_stdext_unix.Unixext.rm_rec (get_repo_config repo_name "gpgdir") ;
+    if Pkg_mgr.(active () = Yum) then
+      Xapi_stdext_unix.Unixext.rm_rec (get_repo_config repo_name "gpgdir") ;
     Xapi_stdext_pervasives.Pervasiveext.finally
       (fun () ->
+        let open Pkg_mgr in
         with_access_token ~token ~token_id @@ fun token_path ->
         (* Configure proxy and token *)
         let token_param =
@@ -152,11 +154,11 @@ let sync ~__context ~self ~token ~token_id =
           ; token_param
           ; repo_name
           ]
+          |> add_sub_cmd Repoconfig
         in
         ignore
           (Helpers.call_script ~log_output:Helpers.On_failure
-             !Xapi_globs.yum_config_manager_cmd
-             config_params
+             (repoconfig_cmd ()) config_params
           ) ;
 
         (* Import YUM repository GPG key to check metadata in reposync *)
@@ -168,7 +170,7 @@ let sync ~__context ~self ~token ~token_id =
           ; "makecache"
           ]
         in
-        ignore (Helpers.call_script !Xapi_globs.yum_cmd makecache_params) ;
+        ignore (Helpers.call_script (pmgr_cmd ()) makecache_params) ;
 
         (* Sync with remote repository *)
         let sync_params =
@@ -178,14 +180,16 @@ let sync ~__context ~self ~token ~token_id =
           ; "--downloadcomps"
           ; "--download-metadata"
           ; "--delete"
-          ; "--plugins"
           ; "--newest-only"
           ; Printf.sprintf "--repoid=%s" repo_name
           ]
+          @ plugins ()
+          |> add_sub_cmd Reposync
         in
+
         Unixext.mkdir_rec !Xapi_globs.local_pool_repo_dir 0o700 ;
         clean_yum_cache repo_name ;
-        ignore (Helpers.call_script !Xapi_globs.reposync_cmd sync_params)
+        ignore (Helpers.call_script (reposync_cmd ()) sync_params)
       )
       (fun () ->
         (* Rewrite repo conf file as initial content to remove credential related info,
@@ -595,7 +599,7 @@ let apply ~__context ~host =
         ; "upgrade"
         ]
       in
-      try ignore (Helpers.call_script !Xapi_globs.yum_cmd params)
+      try ignore (Helpers.call_script (Pkg_mgr.pmgr_cmd ()) params)
       with e ->
         let host' = Ref.string_of host in
         error "Failed to apply updates on host ref='%s': %s" host'

ocaml/xapi/repository_helpers.ml

@@ -274,9 +274,18 @@ let with_updateinfo_xml gz_path f =
 let clean_yum_cache name =
   try
     let params =
-      ["--disablerepo=*"; Printf.sprintf "--enablerepo=%s" name; "clean"; "all"]
+      match name with
+      | "*" ->
+          ["clean"; "all"]
+      | _ ->
+          [
+            "--disablerepo=*"
+          ; Printf.sprintf "--enablerepo=%s" name
+          ; "clean"
+          ; "all"
+          ]
     in
-    ignore (Helpers.call_script !Xapi_globs.yum_cmd params)
+    ignore (Helpers.call_script (Pkg_mgr.pmgr_cmd ()) params)
   with e ->
     warn "Unable to clean YUM cache for %s: %s" name (ExnHelper.string_of_exn e)
 
@@ -349,8 +358,12 @@ let write_yum_config ~source_url ~binary_url ~repo_gpgcheck ~gpgkey_path
   )
 
 let get_repo_config repo_name config_name =
-  let config_params = [repo_name] in
-  Helpers.call_script !Xapi_globs.yum_config_manager_cmd config_params
+  let open Pkg_mgr in
+  let config_params =
+    (match active () with Yum -> [] | Dnf -> ["--dump"]) @ [repo_name]
+    |> add_sub_cmd Repoconfig
+  in
+  Helpers.call_script (repoconfig_cmd ()) config_params
   |> Astring.String.cuts ~sep:"\n"
   |> List.filter_map (fun kv ->
          let prefix = Printf.sprintf "%s = " config_name in
@@ -434,12 +447,10 @@ let with_local_repositories ~__context f =
                    (only to access the repo mirror in the coordinator!) *)
               ; repo_name
               ]
+              |> Pkg_mgr.add_sub_cmd Pkg_mgr.Repoconfig
             in
             ignore
-              (Helpers.call_script
-                 !Xapi_globs.yum_config_manager_cmd
-                 config_params
-              ) ;
+              (Helpers.call_script (Pkg_mgr.repoconfig_cmd ()) config_params) ;
             repo_name
           )
           enabled
@@ -484,20 +495,22 @@ let parse_updateinfo_list acc line =
       acc
 
 let is_obsoleted pkg_name repositories =
+  let open Pkg_mgr in
   let params =
     [
       "-a"
-    ; "--plugins"
     ; "--disablerepo=*"
     ; Printf.sprintf "--enablerepo=%s" (String.concat "," repositories)
     ; "--whatobsoletes"
     ; pkg_name
     ; "--qf"
     ; "%{name}"
     ]
+    @ plugins ()
+    |> add_sub_cmd Repoquery
   in
   match
-    Helpers.call_script !Xapi_globs.repoquery_cmd params
+    Helpers.call_script (repoquery_cmd ()) params
     |> Astring.String.cuts ~sep:"\n" ~empty:false
   with
   | [] ->
@@ -523,7 +536,7 @@ let get_pkgs_from_yum_updateinfo_list sub_command repositories =
     ; sub_command
     ]
   in
-  Helpers.call_script !Xapi_globs.yum_cmd params
+  Helpers.call_script (Pkg_mgr.pmgr_cmd ()) params
   |> assert_yum_error
   |> Astring.String.cuts ~sep:"\n"
   |> List.map (fun x ->
@@ -698,9 +711,20 @@ let parse_line_of_repoquery acc line =
       acc
 
 let get_installed_pkgs () =
+  let open Pkg_mgr in
   let fmt = get_repoquery_fmt () in
-  let params = ["-a"; "--pkgnarrow=installed"; "--qf"; fmt] in
-  Helpers.call_script !Xapi_globs.repoquery_cmd params
+  let params =
+    (["-a"; "--qf"; fmt]
+    @
+    match active () with
+    | Yum ->
+        ["--pkgnarrow=installed"]
+    | Dnf ->
+        ["--installed"]
+    )
+    |> add_sub_cmd Repoquery
+  in
+  Helpers.call_script (repoquery_cmd ()) params
   |> Astring.String.cuts ~sep:"\n"
   |> List.map (fun x ->
          debug "repoquery installed: %s" x ;
@@ -710,19 +734,27 @@ let get_installed_pkgs () =
   |> List.map (fun (pkg, _) -> (Pkg.to_name_arch_string pkg, pkg))
 
 let get_pkgs_from_repoquery pkg_narrow repositories =
+  let open Pkg_mgr in
   let fmt = get_repoquery_fmt () in
   let params =
-    [
-      "-a"
-    ; "--plugins"
-    ; "--disablerepo=*"
-    ; Printf.sprintf "--enablerepo=%s" (String.concat "," repositories)
-    ; Printf.sprintf "--pkgnarrow=%s" pkg_narrow
-    ; "--qf"
-    ; fmt
-    ]
+    ([
+       "-a"
+     ; "--disablerepo=*"
+     ; Printf.sprintf "--enablerepo=%s" (String.concat "," repositories)
+     ; "--qf"
+     ; fmt
+     ]
+    @
+    match active () with
+    | Yum ->
+        [Printf.sprintf "--pkgnarrow=%s" pkg_narrow; "--plugins"]
+    | Dnf ->
+        [Printf.sprintf "--%s" pkg_narrow]
+    )
+    |> add_sub_cmd Repoquery
   in
-  Helpers.call_script !Xapi_globs.repoquery_cmd params
+
+  Helpers.call_script (repoquery_cmd ()) params
   |> Astring.String.cuts ~sep:"\n"
   |> List.map (fun x ->
          debug "repoquery available: %s" x ;
@@ -731,9 +763,13 @@ let get_pkgs_from_repoquery pkg_narrow repositories =
   |> List.fold_left parse_line_of_repoquery []
 
 let get_updates_from_repoquery repositories =
+  let open Pkg_mgr in
+  let updates_arg =
+    match active () with Yum -> "updates" | Dnf -> "upgrades"
+  in
   List.iter (fun r -> clean_yum_cache r) repositories ;
   (* Use 'updates' to decrease the number of packages to apply 'is_obsoleted' *)
-  let updates = get_pkgs_from_repoquery "updates" repositories in
+  let updates = get_pkgs_from_repoquery updates_arg repositories in
   (* 'new_updates' are a list of RPM packages to be installed, rather than updated *)
   let new_updates =
     get_pkgs_from_repoquery "available" repositories
@@ -936,20 +972,25 @@ module YumUpgradeOutput = struct
 end
 
 let get_updates_from_yum_upgrade_dry_run repositories =
+  let open Pkg_mgr in
   let params =
-    [
-      "--disablerepo=*"
-    ; Printf.sprintf "--enablerepo=%s" (String.concat "," repositories)
-    ; "--assumeno"
-    ; "--quiet"
-    ; "upgrade"
-    ]
+    (match active () with Dnf -> [] | Yum -> ["--quiet"])
+    @ [
+        "--disablerepo=*"
+      ; Printf.sprintf "--enablerepo=%s" (String.concat "," repositories)
+      ; "--assumeno"
+      ; "upgrade"
+      ]
   in
-  match Forkhelpers.execute_command_get_output !Xapi_globs.yum_cmd params with
+  match Forkhelpers.execute_command_get_output (pmgr_cmd ()) params with
   | _, _ ->
       Some []
-  | exception Forkhelpers.Spawn_internal_error (stderr, _, Unix.WEXITED 1) -> (
-      stderr |> YumUpgradeOutput.parse_output_of_dry_run |> function
+  | exception Forkhelpers.Spawn_internal_error (stderr, stdout, Unix.WEXITED 1)
+    -> (
+      (*Yum put the details to stderr while dnf to stdout*)
+      (match active () with Yum -> stderr | Dnf -> stdout)
+      |> YumUpgradeOutput.parse_output_of_dry_run
+      |> function
       | Ok (pkgs, Some txn_file) ->
           Unixext.unlink_safe txn_file ;
           Some pkgs

ocaml/xapi/xapi_globs.ml

@@ -909,6 +909,8 @@ let repository_domain_name_allowlist = ref []
 
 let yum_cmd = ref "/usr/bin/yum"
 
+let dnf_cmd = ref "/usr/bin/dnf"
+
 let kpatch_cmd = ref "/usr/sbin/kpatch"
 
 let xen_livepatch_cmd = ref "/usr/sbin/xen-livepatch"

ocaml/xapi/xapi_pool.ml

@@ -3406,7 +3406,9 @@ let sync_updates ~__context ~self ~force ~token ~token_id =
   |> List.iter (fun repo ->
          if force then cleanup_pool_repo ~__context ~self:repo ;
          sync ~__context ~self:repo ~token ~token_id ;
-         create_pool_repository ~__context ~self:repo
+         if Pkg_mgr.(active () = Yum) then
+           (*Dnf sync all the metadata and updateinfo, no need to re-create repo*)
+           create_pool_repository ~__context ~self:repo
      ) ;
   let checksum = set_available_updates ~__context in
   Db.Pool.set_last_update_sync ~__context ~self ~value:(Date.now ()) ;