catch up 7.4.1175

* update ja.po
* README: how to update ja.po
* add helper scripts (copy from vim)
* ignore working files

it will fix #6 and #10

Author: koron

.gitignore

@@ -0,0 +1,2 @@
+/src/po/vim.pot
+/src/po/*.po.old

README.mkd

@@ -13,6 +13,42 @@ runtime/lang/menu\_ja\_jp.utf-8.vim |Vimの日本語メニューファイルの
 
 src/po/ 及び runtime/lang/ 配下の、上記以外のファイルは基本的にマスターから変換するものなので通常直接は編集しないでください。
 
-## 更新手順
+## ja.po 更新手順
 
-(TODO: そのうち書く)
+1.  vim.pot を作成(要xgettext)
+
+    Vimのソースで以下を実行して、生成される vim.pot を src/po へコピー
+
+        $ cd src/po
+        $ make vim.pot
+
+2.  ja.po に vim.pot をマージ (古いのは ja.po.old へ退避)
+
+        $ mv ja.po ja.po.old
+        $ msgmerge ja.po.old vim.pot -o ja.po
+
+3.  ja.po のコピーライトやヘッダーを適宜修正
+
+    これはPRを作るだけの場合は、やらないほうが良いかも。
+
+4.  翻訳する
+
+    Vimを使って下記の検索コマンドで翻訳すべき場所を探すと良い。
+
+        /fuzzy\|^msgstr ""\(\n"\)\@!
+
+5.  不要な情報の削除
+
+    Vim で以下のようにする。
+
+        :source cleanup.vim
+
+    cleanup.vim は Vim 本体からのコピー
+
+6.  チェック
+
+        $ vim -S check.vim ja.po
+
+7.  euc-jp と sjis 版の作成
+
+    本来なら自動化すべきところなので、今は忘れて良い。

src/po/check.vim

@@ -0,0 +1,88 @@
+" Vim script for checking .po files.
+"
+" Go through the file and verify that:
+" - All %...s items in "msgid" are identical to the ones in "msgstr".
+" - An error or warning code in "msgid" matches the one in "msgstr".
+
+if 1	" Only execute this if the eval feature is available.
+
+" Function to get a split line at the cursor.
+" Used for both msgid and msgstr lines.
+" Removes all text except % items and returns the result.
+func! GetMline()
+  let idline = substitute(getline('.'), '"\(.*\)"$', '\1', '')
+  while line('.') < line('$')
+    +
+    let line = getline('.')
+    if line[0] != '"'
+      break
+    endif
+    let idline .= substitute(line, '"\(.*\)"$', '\1', '')
+  endwhile
+
+  " remove '%', not used for formatting.
+  let idline = substitute(idline, "'%'", '', 'g')
+
+  " remove '%' used for plural forms.
+  let idline = substitute(idline, '\\nPlural-Forms: .\+;\\n', '', '')
+
+  " remove everything but % items.
+  return substitute(idline, '[^%]*\(%[-+ #''.0-9*]*l\=[dsuxXpoc%]\)\=', '\1', 'g')
+endfunc
+
+" This only works when 'wrapscan' is set.
+let s:save_wrapscan = &wrapscan
+set wrapscan
+
+" Start at the first "msgid" line.
+1
+/^msgid
+let startline = line('.')
+let error = 0
+
+while 1
+  if getline(line('.') - 1) !~ "no-c-format"
+    let fromline = GetMline()
+    if getline('.') !~ '^msgstr'
+      echo 'Missing "msgstr" in line ' . line('.')
+      let error = 1
+    endif
+    let toline = GetMline()
+    if fromline != toline
+      echo 'Mismatching % in line ' . (line('.') - 1)
+      echo 'msgid: ' . fromline
+      echo 'msgstr: ' . toline
+      let error = 1
+    endif
+  endif
+
+  " Find next msgid.
+  " Wrap around at the end of the file, quit when back at the first one.
+  /^msgid
+  if line('.') == startline
+    break
+  endif
+endwhile
+
+" Check that error code in msgid matches the one in msgstr.
+"
+" Examples of mismatches found with msgid "E123: ..."
+" - msgstr "E321: ..."    error code mismatch
+" - msgstr "W123: ..."    warning instead of error
+" - msgstr "E123 ..."     missing colon
+" - msgstr "..."          missing error code
+"
+1
+if search('msgid "\("\n"\)\?\([EW][0-9]\+:\).*\nmsgstr "\("\n"\)\?[^"]\@=\2\@!') > 0
+  echo 'Mismatching error/warning code in line ' . line('.')
+  let error = 1
+endif
+
+if error == 0
+  echo "OK"
+endif
+
+let &wrapscan = s:save_wrapscan
+unlet s:save_wrapscan
+
+endif

src/po/cleanup.vim

@@ -0,0 +1,19 @@
+" Vim script to cleanup a .po file:
+" - Remove line numbers (avoids that diffs are messy).
+" - Comment-out fuzzy and empty messages.
+" - Make sure there is a space before the string (required for Solaris).
+" Requires Vim 6.0 or later (because of multi-line search patterns).
+
+" Disable diff mode, because it makes this very slow
+let s:was_diff = &diff
+setl nodiff
+
+silent g/^#: /d
+silent g/^#, fuzzy\(, .*\)\=\nmsgid ""\@!/.+1,/^$/-1s/^/#\~ /
+silent g/^msgstr"/s//msgstr "/
+silent g/^msgid"/s//msgid "/
+silent g/^msgstr ""\(\n"\)\@!/?^msgid?,.s/^/#\~ /
+
+if s:was_diff
+  setl diff
+endif