💥 Rewrite everything

- Drop JSON configuration and introduce TypeScript based configuration
- Completely rewritten internal logics and extensions
- Introduce "processor" to improve latency
- Introduce "layout" and "theme" for custom appearance
- Introduce "curator" extension for live-grep
- Introduce "submatch" action for fine-grained selection
- Drop "FallResume" for now

Author: lambdalisue

autoload/fall.vim

@@ -0,0 +1,3 @@
+function! fall#action(name) abort
+  call fall#internal#dispatch(#{type: 'action-invoke', name: a:name})
+endfunction

autoload/fall/command/Fall.vim

@@ -0,0 +1,40 @@
+function! fall#command#Fall#call(args) abort
+  if denops#plugin#wait('fall') isnot# 0
+    return
+  endif
+  let l:laststatus_saved = &laststatus
+  augroup fall_command_Fall
+    autocmd!
+    autocmd CmdlineEnter * call s:hide()
+    autocmd CmdlineLeave * call s:show()
+  augroup END
+  try
+    set laststatus=0
+    call fall#internal#mapping#store()
+    call denops#request('fall', 'picker:start:command', [a:args])
+  finally
+    augroup fall_command_Fall
+      autocmd!
+    augroup END
+    call fall#internal#tolerant#call({ -> fall#internal#mapping#restore() })
+    call fall#internal#tolerant#call({ -> fall#internal#popup#closeall() })
+    let &laststatus = l:laststatus_saved
+  endtry
+endfunction
+
+function! fall#command#Fall#complete(arglead, cmdline, cursorpos) abort
+  if denops#plugin#wait('fall') == 0
+    return []
+  endif
+  return []
+endfunction
+
+function! s:hide() abort
+  call fall#internal#tolerant#call({ -> fall#internal#msgarea#hide() })
+  call fall#internal#tolerant#call({ -> fall#internal#cursor#hide() })
+endfunction
+
+function! s:show() abort
+  call fall#internal#tolerant#call({ -> fall#internal#msgarea#show() })
+  call fall#internal#tolerant#call({ -> fall#internal#cursor#show() })
+endfunction

autoload/fall/command/FallConfig.vim

@@ -0,0 +1,17 @@
+let s:sep = has('win32') ? '\' : '/'
+let s:fall_config_template = join([
+      \ expand('<sfile>:p:h:h:h:h'),
+      \ 'denops',
+      \ 'fall',
+      \ '_assets',
+      \ 'default.config.ts',
+      \], s:sep)
+
+function! fall#command#FallConfig#call() abort
+  let l:path = fnamemodify(expand(g:fall_config_path), ':p')
+  if !filereadable(l:path)
+    call mkdir(fnamemodify(l:path, ':h'), 'p')
+    call writefile(readfile(s:fall_config_template), l:path)
+  endif
+  execute 'vsplit' fnameescape(l:path)
+endfunction

autoload/fall/internal.vim

@@ -0,0 +1,6 @@
+function! fall#internal#dispatch(event) abort
+  if denops#plugin#wait('fall') isnot# 0
+    return
+  endif
+  call denops#request('fall', 'event:dispatch', [a:event])
+endfunction

autoload/fall/internal/cursor.vim

@@ -0,0 +1,45 @@
+let s:t_ve_saved = &t_ve
+
+function! fall#internal#cursor#hide() abort
+  call s:hide_cursor()
+endfunction
+
+function! fall#internal#cursor#show() abort
+  call s:show_cursor()
+endfunction
+
+if has('nvim-0.5.0')
+  function! s:hide_cursor() abort
+    set guicursor+=a:FallTransparentCursor/lCursor
+  endfunction
+
+  function! s:show_cursor() abort
+    set guicursor-=a:FallTransparentCursor/lCursor
+  endfunction
+
+  function! s:highlight() abort
+    highlight FallTransparentCursor gui=strikethrough blend=100
+  endfunction
+  call s:highlight()
+
+  augroup fall_internal_cursor
+    autocmd!
+    autocmd ColorScheme * call s:highlight()
+  augroup END
+elseif has('nvim') || has('gui_running')
+  function! s:hide_cursor() abort
+    set guicursor+=a:ver1
+  endfunction
+
+  function! s:show_cursor() abort
+    let &guicursor = s:guicursor_saved
+  endfunction
+else
+  function! s:hide_cursor() abort
+    set t_ve=
+  endfunction
+
+  function! s:show_cursor() abort
+    let &t_ve = s:t_ve_saved
+  endfunction
+endif

autoload/fall/internal/highlight.vim

@@ -0,0 +1,19 @@
+function! fall#internal#highlight#fast(filetype)
+  let l:eventignore_saved = &eventignore
+  try
+    set eventignore+=FileType
+    call fall#internal#highlight#real(a:filetype)
+  finally
+    let &eventignore = l:eventignore_saved
+  endtry
+  silent! execute printf('runtime syntax/%s.vim', fnameescape(&filetype))
+endfunction
+
+function! fall#internal#highlight#real(filetype)
+  if empty(a:filetype)
+    silent! unlet! b:ftdetect
+    silent! filetype detect
+  else
+    let &filetype = a:filetype
+  endif
+endfunction

autoload/fall/internal/mapping.vim

@@ -0,0 +1,26 @@
+function! fall#internal#mapping#store() abort
+  if exists('s:saved_maps')
+    return
+  endif
+  let s:saved_maps = maplist()->filter({ _, m -> m.mode ==# 'c' || m.mode ==# '!' })
+endfunction
+
+" NOTE:
+"
+" It seems restore step must be called twice to restore the mappings correctly.
+" Otherwise, mappings with recursive references are not restored correctly.
+"
+" For example:
+"
+" cnoremap <Up> <C-p>
+" cnoremap <C-p> <Up>
+"
+function! fall#internal#mapping#restore()
+  if !exists('s:saved_maps')
+    return
+  endif
+  cmapclear
+  call foreach(s:saved_maps, {_, m -> mapset(m)})
+  call foreach(s:saved_maps, {_, m -> mapset(m)})
+  unlet s:saved_maps
+endfunction

autoload/fall/internal/msgarea.vim

@@ -0,0 +1,55 @@
+function! fall#internal#msgarea#hide() abort
+  call s:hide_msgarea()
+  redraw
+endfunction
+
+function! fall#internal#msgarea#show() abort
+  call s:show_msgarea()
+  redraw
+endfunction
+
+if has('nvim')
+  function! s:hide_msgarea() abort
+    if exists('s:hl_msgarea')
+      return
+    endif
+    let s:hl_msgarea = nvim_get_hl(0, #{ name: 'MsgArea' })
+    let l:hl_normal = nvim_get_hl(0, #{ name: 'Normal' })
+    if !has_key(l:hl_normal, 'bg')
+      " guifg=NONE is not supported
+      unlet! s:hl_msgarea
+      return
+    endif
+    call nvim_set_hl(0, 'MsgArea', #{ fg: l:hl_normal.bg, bg: l:hl_normal.bg })
+  endfunction
+
+  function! s:show_msgarea() abort
+    if !exists('s:hl_msgarea')
+      return
+    endif
+    call nvim_set_hl(0, 'MsgArea', s:hl_msgarea)
+    unlet s:hl_msgarea
+  endfunction
+else
+  function! s:hide_msgarea() abort
+    if exists('s:hl_msgarea')
+      return
+    endif
+    let s:hl_msgarea = hlget('MsgArea')
+    let l:hl_normal = hlget('Normal')
+    if !has_key(l:hl_normal[0], 'guibg')
+      " guifg=NONE is not supported
+      unlet! s:hl_msgarea
+      return
+    endif
+    call hlset([#{ name: 'MsgArea', guifg: l:hl_normal[0].guibg, guibg: l:hl_normal[0].guibg }])
+  endfunction
+
+  function! s:show_msgarea() abort
+    if !exists('s:hl_msgarea')
+      return
+    endif
+    call hlset([extend(#{ force: 1 }, s:hl_msgarea[0])])
+    unlet s:hl_msgarea
+  endfunction
+endif

autoload/fall/internal/popup.vim

@@ -0,0 +1,16 @@
+function! fall#internal#popup#closeall() abort
+  let l:winids = range(1, winnr('$'))
+        \ ->map({_, v -> win_getid(v)})
+        \ ->filter({_, v -> win_gettype(v) ==# 'popup'})
+  call foreach(l:winids, {_, v -> s:close(v)})
+endfunction
+
+if has('nvim')
+  function! s:close(winid) abort
+    call nvim_win_close(a:winid, v:true)
+  endfunction
+else
+  function! s:close(winid) abort
+    call popup_close(a:winid)
+  endfunction
+endif

autoload/fall/internal/tolerant.vim

@@ -0,0 +1,11 @@
+function! fall#internal#tolerant#call(calback) abort
+  try
+    call a:calback()
+  catch
+    if &verbose
+      echohl WarningMsg
+      echomsg printf('[fall] Error on tolerant call: %s', v:exception)
+      echohl None
+    endif
+  endtry
+endfunction