rabbit_db: Add init/0 function

This function sits on top of `rabbit_mnesia:init/0`. In the future, it
will take care of initializing the right database layer, whatever it is.

The start of `mnesia_sync` is now part of this initialization instead of
a separate boot step in `rabbit` because its is specific to our use of
Mnesia.

This patch also introduces the following functions:
* `is_virgin_node/0`
* `dir/0`

They also wrap the same functions in `rabbit_mnesia`.

In addition, `rabbit_db` provides `is_virgin_node/1` to query the state
of a remote node. This is used by `rabbit_ff_controller` in the feature
flags subsystem.

At this point, the underlying equivalent functions in `rabbit_mnesia`
become private to this module (and other modules implementing the
interaction with Mnesia). Other parts of RabbitMQ, including plugins,
should now use `rabbit_db`, not `rabbit_mnesia`.

Author: dumbbell

deps/rabbit/src/rabbit.erl

@@ -64,16 +64,10 @@
                     {enables,     external_infrastructure}]}).
 
 -rabbit_boot_step({database,
-                   [{mfa,         {rabbit_mnesia, init, []}},
+                   [{mfa,         {rabbit_db, init, []}},
                     {requires,    file_handle_cache},
                     {enables,     external_infrastructure}]}).
 
--rabbit_boot_step({database_sync,
-                   [{description, "database sync"},
-                    {mfa,         {rabbit_sup, start_child, [mnesia_sync]}},
-                    {requires,    database},
-                    {enables,     external_infrastructure}]}).
-
 -rabbit_boot_step({networking_metadata_store,
                    [{description, "networking infrastructure"},
                     {mfa,         {rabbit_sup, start_child, [rabbit_networking_store]}},
@@ -1113,7 +1107,6 @@ get_default_data_param(Param) ->
 
 data_dir() ->
     {ok, DataDir} = application:get_env(rabbit, data_dir),
-    ?assertEqual(DataDir, rabbit_mnesia:dir()),
     DataDir.
 
 %%---------------------------------------------------------------------------

deps/rabbit/src/rabbit_db.erl

@@ -10,8 +10,100 @@
 -include_lib("kernel/include/logger.hrl").
 -include_lib("stdlib/include/assert.hrl").
 
+-include_lib("rabbit_common/include/logging.hrl").
+
+-export([init/0,
+         is_virgin_node/0, is_virgin_node/1,
+         dir/0]).
 -export([run/1]).
 
+%% Default timeout for operations on remote nodes.
+-define(TIMEOUT, 60000).
+
+%% -------------------------------------------------------------------
+%% DB initialization.
+%% -------------------------------------------------------------------
+
+-spec init() -> Ret when
+      Ret :: ok | {error, any()}.
+%% @doc Initializes the DB layer.
+
+init() ->
+    IsVirgin = is_virgin_node(),
+    ?LOG_DEBUG(
+       "DB: this node is virgin: ~ts",
+       [IsVirgin],
+       #{domain => ?RMQLOG_DOMAIN_DB}),
+    case init_mnesia() of
+        ok ->
+            ?LOG_DEBUG(
+               "DB: initialization successeful",
+               #{domain => ?RMQLOG_DOMAIN_DB}),
+            ok;
+        Error ->
+            ?LOG_DEBUG(
+               "DB: initialization failed: ~0p",
+               [Error],
+               #{domain => ?RMQLOG_DOMAIN_DB}),
+            Error
+    end.
+
+init_mnesia() ->
+    ?LOG_DEBUG(
+      "DB: initialize Mnesia",
+      #{domain => ?RMQLOG_DOMAIN_DB}),
+    ok = rabbit_mnesia:init(),
+    ?assertEqual(rabbit:data_dir(), mnesia_dir()),
+    rabbit_sup:start_child(mnesia_sync).
+
+-spec is_virgin_node() -> IsVirgin when
+      IsVirgin :: boolean().
+%% @doc Indicates if this RabbitMQ node is virgin.
+%%
+%% @returns `true' if the node is virgin, `false' if it is not.
+%%
+%% @see is_virgin_node/1.
+
+is_virgin_node() ->
+    ThisNode = node(),
+    is_virgin_node(ThisNode).
+
+-spec is_virgin_node(Node) -> IsVirgin | undefined when
+      Node :: node(),
+      IsVirgin :: boolean().
+%% @doc Indicates if the given RabbitMQ node is virgin.
+%%
+%% A virgin node is a node starting for the first time. It could be a brand
+%% new node or a node having been reset.
+%%
+%% @returns `true' if the node is virgin, `false' if it is not, or `undefined'
+%% if the given node is remote and we couldn't determine it.
+
+is_virgin_node(Node) when is_atom(Node) ->
+    is_virgin_node_with_mnesia(Node).
+
+is_virgin_node_with_mnesia(Node) when Node =:= node() ->
+    rabbit_mnesia:is_virgin_node();
+is_virgin_node_with_mnesia(Node) ->
+    try
+        erpc:call(Node, rabbit_mnesia, is_virgin_node, [], ?TIMEOUT)
+    catch
+        _:_ ->
+            undefined
+    end.
+
+-spec dir() -> DBDir when
+      DBDir :: file:filename().
+%% @doc Returns the directory where the database stores its data.
+%%
+%% @returns the directory path.
+
+dir() ->
+    mnesia_dir().
+
+mnesia_dir() ->
+    rabbit_mnesia:dir().
+
 %% -------------------------------------------------------------------
 %% run().
 %% -------------------------------------------------------------------

deps/rabbit/src/rabbit_ff_controller.erl

@@ -762,7 +762,7 @@ check_required_and_enable(
                            VirginNodesWhereDisabled =
                            lists:filter(
                              fun(Node) ->
-                                     case is_virgin_node(Node) of
+                                     case rabbit_db:is_virgin_node(Node) of
                                          IsVirgin when is_boolean(IsVirgin) ->
                                              IsVirgin;
                                          undefined ->
@@ -853,14 +853,6 @@ update_feature_state_and_enable(
             Error
     end.
 
-is_virgin_node(Node) ->
-    case rpc_call(Node, rabbit_mnesia, is_virgin_node, [], ?TIMEOUT) of
-        IsVirgin when is_boolean(IsVirgin) ->
-            IsVirgin;
-        {error, _} ->
-            undefined
-    end.
-
 restore_feature_flag_state(
   Nodes, NodesWhereDisabled, Inventory, FeatureName) ->
     NodesWhereEnabled = Nodes -- NodesWhereDisabled,

deps/rabbit/src/rabbit_node_monitor.erl

@@ -62,12 +62,12 @@ start_link() -> gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).
 -spec running_nodes_filename() -> string().
 
 running_nodes_filename() ->
-    filename:join(rabbit_mnesia:dir(), "nodes_running_at_shutdown").
+    filename:join(rabbit:data_dir(), "nodes_running_at_shutdown").
 
 -spec cluster_status_filename() -> string().
 
 cluster_status_filename() ->
-    filename:join(rabbit_mnesia:dir(), "cluster_nodes.config").
+    filename:join(rabbit:data_dir(), "cluster_nodes.config").
 
 coordination_filename() ->
     filename:join(rabbit:data_dir(), "coordination").

deps/rabbit/test/feature_flags_v2_SUITE.erl

@@ -1272,11 +1272,11 @@ have_required_feature_flag_in_cluster_and_add_member_without_it(
                    ?assert(rabbit_feature_flags:is_supported(FeatureName)),
                    ?assertNot(rabbit_feature_flags:is_enabled(FeatureName)),
 
-                   MnesiaDir = rabbit_mnesia:dir(),
-                   ok = filelib:ensure_path(MnesiaDir),
-                   SomeFile = filename:join(MnesiaDir, "some-mnesia-file.db"),
+                   DBDir = rabbit_db:dir(),
+                   ok = filelib:ensure_path(DBDir),
+                   SomeFile = filename:join(DBDir, "some-file.db"),
                    ok = file:write_file(SomeFile, <<>>),
-                   ?assertNot(rabbit_mnesia:is_virgin_node()),
+                   ?assertNot(rabbit_db:is_virgin_node()),
                    ok
            end,
            []),