Merge pull request #14 from hdgarrood/conversions-from-number

Add more conversions from `Number`

Author: paf31

bower.json

@@ -21,7 +21,8 @@
     "package.json"
   ],
   "dependencies": {
-    "purescript-maybe": "^0.3.0"
+    "purescript-maybe": "^0.3.0",
+    "purescript-math": "^0.2.0"
   },
   "devDependencies": {
     "purescript-assert": "^0.1.0",

docs/Data/Int.md

@@ -10,6 +10,33 @@ Creates an `Int` from a `Number` value. The number must already be an
 integer and fall within the valid range of values for the `Int` type
 otherwise `Nothing` is returned.
 
+#### `floor`
+
+``` purescript
+floor :: Number -> Int
+```
+
+Convert a `Number` to an `Int`, by taking the closest integer equal to or
+less than the argument. Values outside the `Int` range are clamped.
+
+#### `ceil`
+
+``` purescript
+ceil :: Number -> Int
+```
+
+Convert a `Number` to an `Int`, by taking the closest integer equal to or
+greater than the argument. Values outside the `Int` range are clamped.
+
+#### `round`
+
+``` purescript
+round :: Number -> Int
+```
+
+Convert a `Number` to an `Int`, by taking the nearest integer to the
+argument. Values outside the `Int` range are clamped.
+
 #### `toNumber`
 
 ``` purescript

src/Data/Int.purs

@@ -1,5 +1,8 @@
 module Data.Int
   ( fromNumber
+  , ceil
+  , floor
+  , round
   , toNumber
   , fromString
   , even
@@ -10,6 +13,8 @@ import Prelude
 
 import Data.Int.Bits
 import Data.Maybe (Maybe(..))
+import qualified Data.Maybe.Unsafe as U
+import qualified Math as Math
 
 -- | Creates an `Int` from a `Number` value. The number must already be an
 -- | integer and fall within the valid range of values for the `Int` type
@@ -22,6 +27,30 @@ foreign import fromNumberImpl :: (forall a. a -> Maybe a)
                               -> Number
                               -> Maybe Int
 
+-- | Convert a `Number` to an `Int`, by taking the closest integer equal to or
+-- | less than the argument. Values outside the `Int` range are clamped.
+floor :: Number -> Int
+floor = unsafeClamp <<< Math.floor
+
+-- | Convert a `Number` to an `Int`, by taking the closest integer equal to or
+-- | greater than the argument. Values outside the `Int` range are clamped.
+ceil :: Number -> Int
+ceil = unsafeClamp <<< Math.ceil
+
+-- | Convert a `Number` to an `Int`, by taking the nearest integer to the
+-- | argument. Values outside the `Int` range are clamped.
+round :: Number -> Int
+round = unsafeClamp <<< Math.round
+
+-- | Convert an integral `Number` to an `Int`, by clamping to the `Int` range.
+-- | This function will throw an error at runtime if the argument is
+-- | non-integral.
+unsafeClamp :: Number -> Int
+unsafeClamp x
+  | x >= toNumber (top :: Int)    = top
+  | x <= toNumber (bottom :: Int) = bottom
+  | otherwise                     = U.fromJust $ fromNumber x
+
 -- | Converts an `Int` value back into a `Number`. Any `Int` is a valid `Number`
 -- | so there is no loss of precision with this function.
 foreign import toNumber :: Int -> Number

test/Test/Data/Int.purs

@@ -23,6 +23,30 @@ testInt = do
   assert $ toNumber (-1) == -1.0
   assert $ toNumber 0 == 0.0
 
+  log "round should choose the closest integer"
+  assert $ round 0.3 == 0
+  assert $ round 0.7 == 1
+
+  log "ceil should round up"
+  assert $ ceil 0.3 == 1
+  assert $ ceil 0.7 == 1
+
+  log "floor should round down"
+  assert $ floor 0.3 == 0
+  assert $ floor 0.7 == 0
+
+  log "round, ceil, and floor should clamp values outside the Int range"
+  let testClamping f = do
+        let low = toNumber bottom - 1.5
+        assert $ f low == bottom
+
+        let high = toNumber top + 1.5
+        assert $ f high == top
+
+  testClamping round
+  testClamping ceil
+  testClamping floor
+
   log "fromString should read integers"
   assert $ fromString "0" == Just 0
   assert $ fromString "9467" == Just 9467