ompi_fortran_get_alignment.m4: fix test

LOC() is not a universal Fortran function (perhaps it's a GNU
extension that at least some Fortran compilers have adopted?  It
doesn't seem to exist in the NAG compiler, at least).

Additionally, doing the pointer arithmetic is not technically valid
Fortran.  So make the test for mpi_f08 handle alignment be similar to
the other alignment tests: make instances of the variable in a common
block and use C to compute the alignment.

Signed-off-by: Jeff Squyres <[email protected]>

Author: jsquyres

config/ompi_fortran_get_alignment.m4

@@ -136,44 +136,78 @@ EOF
 # OMPI_FORTRAN_F08_GET_HANDLE_ALIGNMENT(type, variable to set)
 # ------------------------------------------
 AC_DEFUN([OMPI_FORTRAN_F08_GET_HANDLE_ALIGNMENT],[
+    unset happy
+    OPAL_VAR_SCOPE_PUSH([happy ompi_conftest_h])
+
     # Use of m4_translit suggested by Eric Blake:
     # http://lists.gnu.org/archive/html/bug-autoconf/2010-10/msg00016.html
     AS_VAR_PUSHDEF([type_var],
        m4_translit([[ompi_cv_fortran_alignment_$1]], [*], [p]))
 
     AC_CACHE_CHECK([alignment of Fortran $1], type_var,
-        [AC_LANG_PUSH([Fortran])
-         AC_LINK_IFELSE([AC_LANG_SOURCE([[module alignment_mod
-type, BIND(C) :: test_mpi_handle
-  integer :: MPI_VAL
-end type test_mpi_handle
-type(test_mpi_handle) :: t1
-type(test_mpi_handle) :: t2
-end module
-
-program falignment
-   use alignment_mod
-   OPEN(UNIT=10, FILE="conftestval")
-   if (LOC(t1) > LOC(t2)) then
-      write (10,'(I5)') LOC(t1)-LOC(t2)
-   else
-      write (10,'(I5)') LOC(t2)-LOC(t1)
-   endif
-   CLOSE(10)
-
-end program]])],
-                          [AS_IF([test "$cross_compiling" = "yes"],
-                                 [AC_MSG_ERROR([Can not determine alignment of $1 when cross-compiling])],
-                                 [OPAL_LOG_COMMAND([./conftest],
-                                                   [AS_VAR_SET(type_var, [`cat conftestval`])],
-                                                   [AC_MSG_ERROR([Could not determine alignment of $1])])])],
-
-                          [AC_MSG_WARN([Could not determine alignment of $1])
-                           AC_MSG_WARN([See config.log for details])
-                           AC_MSG_ERROR([Cannot continue])])
-         rm -rf conftest* *.mod 2> /dev/null
-         AC_LANG_POP([Fortran])])
+       [OMPI_FORTRAN_MAKE_C_FUNCTION([ompi_ac_align_fn], [align])
+        # Fortran module
+        cat > conftestf.f <<EOF
+      program falign
+      external align
+      type, BIND(C) :: test_mpi_handle
+        integer :: MPI_VAL
+      end type test_mpi_handle
+      type(test_mpi_handle) :: w,x,y,z
+      CHARACTER a,b,c
+      common /foo/a,w,b,x,y,c,z
+      call align(w,x,y,z)
+      end
+EOF
+
+        # C module
+        if test -f conftest.h; then
+            ompi_conftest_h="#include \"conftest.h\""
+        else
+            ompi_conftest_h=""
+        fi
+        cat > conftest.c <<EOF
+#include <stdio.h>
+#include <stdlib.h>
+
+void $ompi_ac_align_fn(char *w, char *x, char *y, char *z)
+{
+    unsigned long aw, ax, ay, az;
+    FILE *f = fopen("conftestval", "w");
+    if (!f) exit(1);
+    aw = (unsigned long) w;
+    ax = (unsigned long) x;
+    ay = (unsigned long) y;
+    az = (unsigned long) z;
+    if (! ((aw%16)||(ax%16)||(ay%16)||(az%16))) fprintf(f, "%d\n", 16);
+    else if (! ((aw%12)||(ax%12)||(ay%12)||(az%12))) fprintf(f, "%d\n", 12);
+    else if (! ((aw%8)||(ax%8)||(ay%8)||(az%8))) fprintf(f, "%d\n", 8);
+    else if (! ((aw%4)||(ax%4)||(ay%4)||(az%4))) fprintf(f, "%d\n", 4);
+    else if (! ((aw%2)||(ax%2)||(ay%2)||(az%2))) fprintf(f, "%d\n", 2);
+    else fprintf(f, "%d\n", 1);
+    fclose(f);
+}
+EOF
+
+        OPAL_LOG_COMMAND([$CC $CFLAGS -I. -c conftest.c],
+            [OPAL_LOG_COMMAND([$FC $FCFLAGS conftestf.f conftest.o -o conftest $LDFLAGS $LIBS],
+                [happy="yes"], [happy="no"])], [happy="no"])
+
+        if test "$happy" = "no" ; then
+            AC_MSG_RESULT([Error!])
+            AC_MSG_ERROR([Could not determine alignment of $1])
+        fi
+
+        AS_IF([test "$cross_compiling" = "yes"],
+            [AC_MSG_RESULT([Error!])
+             AC_MSG_ERROR([Can not determine alignment of $1 when cross-compiling])],
+            [OPAL_LOG_COMMAND([./conftest],
+                [AS_VAR_SET(type_var, [`cat conftestval`])],
+                [AC_MSG_RESULT([Error!])
+                 AC_MSG_ERROR([Could not determine alignment of $1])])])
+        rm -rf conftest*])
 
     AS_VAR_COPY([$2], [type_var])
     AS_VAR_POPDEF([type_var])dnl
+    OPAL_VAR_SCOPE_POP
 ])dnl