Bookmark a folder

[Trid-collab]

Is it possible to bookmark folders so that we could jump back and forth ? Could you help me with it .

[kyazdani42]

hello, sorry for the delays.
I think you could implement that on your end i believe, i'm not too sure i want to add that in the plugin right now because the codebase is getting a little messy and i'd like to fix bugs and do some refactorings before adding new features that would affect the existing codebase. I wouldn't be against this feature though.
You could maybe just write a lua function that gets the directory cwd on a node ? something like

local lib = require'nvim-tree.lib'
local bookmarks = {}
  
local function add_mark() 
  local node = lib.get_node_at_cursor()
  bookmarks[node.absolute_path] = node.absolute_path
end

local function remove_mark()
  local node = lib.get_node_at_cursor()
  bookmarks[node.absolute_path] = nil
end

local function jump_to_dir(dirname)
  lib.change_dir(dirname)
end

or something like that

[r7vme]

@kyazdani42 thanks for your plugin. After migrating from nerdtree to nvim-tree, this is definitely really desired feature. I work on projects that have hundreds of nested in many levels subprojects (monorepo), so I was relying on bookmarks in nerdtree.

[kyazdani42]

I'll try to finish #612 that will be a first step towards implementing this i think. When i have some time.
If someone wants to give it a shot, go for it :)

[AlecMcCutcheon]

I found this vim script that has the right idea, but would need to be adapted for these commands and also converted to lua.

set viminfo+=!

if !exists('g:BOOKMARKS')
  let g:BOOKMARKS = {}
endif

" Add the current [filename, cursor position] in g:BOOKMARKS under the given
" name
command! -nargs=1 Bookmark call s:Bookmark(<f-args>)
function! s:Bookmark(name)
  let file   = expand('%:p')
  let cursor = getpos('.')

  if file != ''
    let g:BOOKMARKS[a:name] = [file, cursor]
  else
    echom "No file"
  endif

  wviminfo
endfunction

" Delete the user-chosen bookmark
command! -nargs=1 -complete=custom,s:BookmarkNames DelBookmark call s:DelBookmark(<f-args>)
function! s:DelBookmark(name)
  if !has_key(g:BOOKMARKS, a:name)
    return
  endif

  call remove(g:BOOKMARKS, a:name)
  wviminfo
endfunction

" Go to the user-chosen bookmark
command! -nargs=1 -complete=custom,s:BookmarkNames GotoBookmark call s:GotoBookmark(<f-args>)
function! s:GotoBookmark(name)
  if !has_key(g:BOOKMARKS, a:name)
    return
  endif

  let [filename, cursor] = g:BOOKMARKS[a:name]

  exe 'edit '.filename
  call setpos('.', cursor)
endfunction

" Open all bookmarks in the quickfix window
command! CopenBookmarks call s:CopenBookmarks()
function! s:CopenBookmarks()
  let choices = []

  for [name, place] in items(g:BOOKMARKS)
    let [filename, cursor] = place

    call add(choices, {
          \ 'text':     name,
          \ 'filename': filename,
          \ 'lnum':     cursor[1],
          \ 'col':      cursor[2]
          \ })
  endfor

  call setqflist(choices)
  copen
endfunction

" Completion function for choosing bookmarks
function! s:BookmarkNames(A, L, P)
  return join(sort(keys(g:BOOKMARKS)), "\n")
endfunction