Introduce a delegate class for gpu metal rendering

This supports rendering to CAMetalLayer and also MTLTexture.

Author: iskakaushik

shell/common/animator.cc

@@ -29,9 +29,9 @@ Animator::Animator(Delegate& delegate,
       last_vsync_start_time_(),
       last_frame_target_time_(),
       dart_frame_deadline_(0),
-#if FLUTTER_SHELL_ENABLE_METAL
+#if SHELL_ENABLE_METAL
       layer_tree_pipeline_(fml::MakeRefCounted<LayerTreePipeline>(2)),
-#else   // FLUTTER_SHELL_ENABLE_METAL
+#else   // SHELL_ENABLE_METAL
       // TODO(dnfield): We should remove this logic and set the pipeline depth
       // back to 2 in this case. See
       // https://github.com/flutter/engine/pull/9132 for discussion.
@@ -40,7 +40,7 @@ Animator::Animator(Delegate& delegate,
                   task_runners.GetRasterTaskRunner()
               ? 1
               : 2)),
-#endif  // FLUTTER_SHELL_ENABLE_METAL
+#endif  // SHELL_ENABLE_METAL
       pending_frame_semaphore_(1),
       frame_number_(1),
       paused_(false),

shell/gpu/BUILD.gn

@@ -51,6 +51,8 @@ source_set("gpu_surface_metal") {
   sources = [
     "gpu_surface_metal.h",
     "gpu_surface_metal.mm",
+    "gpu_surface_metal_delegate.cc",
+    "gpu_surface_metal_delegate.h",
   ]
 
   deps = gpu_common_deps

shell/gpu/gpu_surface_metal.h

@@ -5,36 +5,31 @@
 #ifndef FLUTTER_SHELL_GPU_GPU_SURFACE_METAL_H_
 #define FLUTTER_SHELL_GPU_GPU_SURFACE_METAL_H_
 
-#include <Metal/Metal.h>
-
 #include "flutter/flow/surface.h"
 #include "flutter/fml/macros.h"
-#include "flutter/fml/platform/darwin/scoped_nsobject.h"
+#include "flutter/shell/gpu/gpu_surface_metal_delegate.h"
 #include "third_party/skia/include/gpu/GrDirectContext.h"
 #include "third_party/skia/include/gpu/mtl/GrMtlTypes.h"
 
-@class CAMetalLayer;
-
 namespace flutter {
 
 class SK_API_AVAILABLE_CA_METAL_LAYER GPUSurfaceMetal : public Surface {
  public:
-  GPUSurfaceMetal(fml::scoped_nsobject<CAMetalLayer> layer,
-                  sk_sp<GrDirectContext> context,
-                  fml::scoped_nsprotocol<id<MTLCommandQueue>> command_queue);
+  GPUSurfaceMetal(GPUSurfaceMetalDelegate* delegate,
+                  sk_sp<GrDirectContext> context);
 
   // |Surface|
   ~GPUSurfaceMetal();
 
+  // |Surface|
+  bool IsValid() override;
+
  private:
-  fml::scoped_nsobject<CAMetalLayer> layer_;
+  const GPUSurfaceMetalDelegate* delegate_;
+  const MTLRenderTargetType render_target_type_;
   sk_sp<GrDirectContext> context_;
-  fml::scoped_nsprotocol<id<MTLCommandQueue>> command_queue_;
   GrMTLHandle next_drawable_ = nullptr;
 
-  // |Surface|
-  bool IsValid() override;
-
   // |Surface|
   std::unique_ptr<SurfaceFrame> AcquireFrame(const SkISize& size) override;
 
@@ -47,6 +42,12 @@ class SK_API_AVAILABLE_CA_METAL_LAYER GPUSurfaceMetal : public Surface {
   // |Surface|
   std::unique_ptr<GLContextResult> MakeRenderContextCurrent() override;
 
+  std::unique_ptr<SurfaceFrame> AcquireFrameFromMTLLayer(
+      const MTLFrameInfo& frame_info);
+
+  std::unique_ptr<SurfaceFrame> AcquireFrameFromMTLTexture(
+      const MTLFrameInfo& frame_info);
+
   void ReleaseUnusedDrawableIfNecessary();
 
   FML_DISALLOW_COPY_AND_ASSIGN(GPUSurfaceMetal);

shell/gpu/gpu_surface_metal.mm

@@ -4,9 +4,10 @@
 
 #include "flutter/shell/gpu/gpu_surface_metal.h"
 
-#include <QuartzCore/CAMetalLayer.h>
+#import <Metal/Metal.h>
 
 #include "flutter/fml/trace_event.h"
+#include "flutter/shell/gpu/gpu_surface_metal_delegate.h"
 #include "third_party/skia/include/core/SkSurface.h"
 #include "third_party/skia/include/gpu/GrBackendSurface.h"
 #include "third_party/skia/include/ports/SkCFObject.h"
@@ -15,25 +16,18 @@
 
 namespace flutter {
 
-GPUSurfaceMetal::GPUSurfaceMetal(fml::scoped_nsobject<CAMetalLayer> layer,
-                                 sk_sp<GrDirectContext> context,
-                                 fml::scoped_nsprotocol<id<MTLCommandQueue>> command_queue)
-    : layer_(std::move(layer)),
-      context_(std::move(context)),
-      command_queue_(std::move(command_queue)) {
-  layer_.get().pixelFormat = MTLPixelFormatBGRA8Unorm;
-  // Flutter needs to read from the color attachment in cases where there are effects such as
-  // backdrop filters.
-  layer_.get().framebufferOnly = NO;
-}
+GPUSurfaceMetal::GPUSurfaceMetal(GPUSurfaceMetalDelegate* delegate, sk_sp<GrDirectContext> context)
+    : delegate_(delegate),
+      render_target_type_(delegate->GetRenderTargetType()),
+      context_(std::move(context)) {}
 
 GPUSurfaceMetal::~GPUSurfaceMetal() {
   ReleaseUnusedDrawableIfNecessary();
 }
 
 // |Surface|
 bool GPUSurfaceMetal::IsValid() {
-  return layer_ && context_ && command_queue_;
+  return context_ != nullptr;
 }
 
 // |Surface|
@@ -48,21 +42,34 @@
     return nullptr;
   }
 
-  const auto drawable_size = CGSizeMake(frame_size.width(), frame_size.height());
+  ReleaseUnusedDrawableIfNecessary();
 
-  if (!CGSizeEqualToSize(drawable_size, layer_.get().drawableSize)) {
-    layer_.get().drawableSize = drawable_size;
+  MTLFrameInfo frame_info;
+  frame_info.height = frame_size.height();
+  frame_info.width = frame_size.width();
+
+  switch (render_target_type_) {
+    case MTLRenderTargetType::kCAMetalLayer:
+      return AcquireFrameFromMTLLayer(frame_info);
+    case MTLRenderTargetType::kMTLTexture:
+      return AcquireFrameFromMTLTexture(frame_info);
+    default:
+      FML_CHECK(false) << "unknown render target type!";
   }
 
-  ReleaseUnusedDrawableIfNecessary();
+  return nullptr;
+}
 
-  // When there are platform views in the scene, the drawable needs to be presented in the same
-  // transaction as the one created for platform views. When the drawable are being presented from
-  // the raster thread, there is no such transaction.
-  layer_.get().presentsWithTransaction = [[NSThread currentThread] isMainThread];
+std::unique_ptr<SurfaceFrame> GPUSurfaceMetal::AcquireFrameFromMTLLayer(
+    const MTLFrameInfo& frame_info) {
+  auto layer = delegate_->GetCAMetalLayer(frame_info);
+  if (!layer) {
+    FML_LOG(ERROR) << "Invalid CAMetalLayer given by the embedder.";
+    return nullptr;
+  }
 
   auto surface = SkSurface::MakeFromCAMetalLayer(context_.get(),            // context
-                                                 layer_.get(),              // layer
+                                                 layer,                     // layer
                                                  kTopLeft_GrSurfaceOrigin,  // origin
                                                  1,                         // sample count
                                                  kBGRA_8888_SkColorType,    // color type
@@ -72,7 +79,7 @@
   );
 
   if (!surface) {
-    FML_LOG(ERROR) << "Could not create the SkSurface from the metal texture.";
+    FML_LOG(ERROR) << "Could not create the SkSurface from the CAMetalLayer.";
     return nullptr;
   }
 
@@ -85,23 +92,48 @@
 
     canvas->flush();
 
-    if (next_drawable_ == nullptr) {
-      FML_DLOG(ERROR) << "Could not acquire next Metal drawable from the SkSurface.";
-      return false;
-    }
+    bool present_result = delegate_->PresentDrawable(next_drawable_);
+    next_drawable_ = nullptr;
+    return present_result;
+  };
 
-    auto command_buffer =
-        fml::scoped_nsprotocol<id<MTLCommandBuffer>>([[command_queue_.get() commandBuffer] retain]);
+  return std::make_unique<SurfaceFrame>(std::move(surface), true, submit_callback);
+}
 
-    fml::scoped_nsprotocol<id<CAMetalDrawable>> drawable(
-        reinterpret_cast<id<CAMetalDrawable>>(next_drawable_));
-    next_drawable_ = nullptr;
+std::unique_ptr<SurfaceFrame> GPUSurfaceMetal::AcquireFrameFromMTLTexture(
+    const MTLFrameInfo& frame_info) {
+  GPUMTLTextureInfo texture = delegate_->GetMTLTexture(frame_info);
+  id<MTLTexture> mtl_texture = (id<MTLTexture>)(texture.texture);
+
+  if (!mtl_texture) {
+    FML_LOG(ERROR) << "Invalid MTLTexture given by the embedder.";
+    return nullptr;
+  }
+
+  GrMtlTextureInfo info;
+  info.fTexture.reset([mtl_texture retain]);
+  GrBackendTexture backend_texture(frame_info.width, frame_info.height, GrMipmapped::kNo, info);
+
+  auto surface =
+      SkSurface::MakeFromBackendTexture(context_.get(), backend_texture, kTopLeft_GrSurfaceOrigin,
+                                        1, kBGRA_8888_SkColorType, nullptr, nullptr);
 
-    [command_buffer.get() commit];
-    [command_buffer.get() waitUntilScheduled];
-    [drawable.get() present];
+  if (!surface) {
+    FML_LOG(ERROR) << "Could not create the SkSurface from the metal texture.";
+    return nullptr;
+  }
+
+  auto submit_callback = [texture_id = texture.texture_id, this](const SurfaceFrame& surface_frame,
+                                                                 SkCanvas* canvas) -> bool {
+    TRACE_EVENT0("flutter", "GPUSurfaceMetal::PresentTexture");
+    if (canvas == nullptr) {
+      FML_DLOG(ERROR) << "Canvas not available.";
+      return false;
+    }
+
+    canvas->flush();
 
-    return true;
+    return delegate_->PresentTexture(texture_id);
   };
 
   return std::make_unique<SurfaceFrame>(std::move(surface), true, submit_callback);

shell/gpu/gpu_surface_metal_delegate.cc

@@ -0,0 +1,19 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "flutter/shell/gpu/gpu_surface_metal_delegate.h"
+
+namespace flutter {
+
+GPUSurfaceMetalDelegate::GPUSurfaceMetalDelegate(
+    MTLRenderTargetType render_target_type)
+    : render_target_type_(render_target_type) {}
+
+GPUSurfaceMetalDelegate::~GPUSurfaceMetalDelegate() = default;
+
+MTLRenderTargetType GPUSurfaceMetalDelegate::GetRenderTargetType() {
+  return render_target_type_;
+}
+
+}  // namespace flutter

shell/gpu/gpu_surface_metal_delegate.h

@@ -0,0 +1,103 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_SHELL_GPU_GPU_SURFACE_METAL_DELEGATE_H_
+#define FLUTTER_SHELL_GPU_GPU_SURFACE_METAL_DELEGATE_H_
+
+#include <stdint.h>
+
+#include "flutter/fml/macros.h"
+#include "third_party/skia/include/core/SkSurface.h"
+#include "third_party/skia/include/gpu/mtl/GrMtlTypes.h"
+
+namespace flutter {
+
+struct MTLFrameInfo {
+  uint32_t width;
+  uint32_t height;
+};
+
+// expected to be id<MTLDevice>
+typedef void* GPUMTLDeviceHandle;
+
+// expected to be id<MTLCommandQueues>
+typedef void* GPUMTLCommandQueueHandle;
+
+// expected to be CAMetalLayer*
+typedef void* GPUMTLLayerHandle;
+
+// expected to be id<MTLTexture>
+typedef void* GPUMTLTextureHandle;
+
+struct GPUMTLTextureInfo {
+  intptr_t texture_id;
+  GPUMTLTextureHandle texture;
+};
+
+enum class MTLRenderTargetType { kMTLTexture, kCAMetalLayer };
+
+//------------------------------------------------------------------------------
+/// @brief      Interface implemented by all platform surfaces that can present
+///             a metal backing store to the "screen". The GPU surface
+///             abstraction (which abstracts the client rendering API) uses this
+///             delegation pattern to tell the platform surface (which abstracts
+///             how backing stores fulfilled by the selected client rendering
+///             API end up on the "screen" on a particular platform) when the
+///             rasterizer needs to allocate and present the software backing
+///             store.
+///
+/// @see        |IOSurfaceMetal| and |EmbedderSurfaceMetal|.
+///
+class GPUSurfaceMetalDelegate {
+ public:
+  //------------------------------------------------------------------------------
+  /// @brief Construct a new GPUSurfaceMetalDelegate object with the specified
+  /// render_target type.
+  ///
+  /// @see |MTLRenderTargetType|
+  ///
+  explicit GPUSurfaceMetalDelegate(MTLRenderTargetType render_target);
+
+  virtual ~GPUSurfaceMetalDelegate();
+
+  //------------------------------------------------------------------------------
+  /// @brief Returns the handle to the CAMetalLayer to render to. This is only
+  /// called when the specifed render target type is `kCAMetalLayer`.
+  ///
+  virtual GPUMTLLayerHandle GetCAMetalLayer(MTLFrameInfo frame_info) const = 0;
+
+  //------------------------------------------------------------------------------
+  /// @brief Presents the drawable to the "screen". The drawable is obtained
+  /// from the CAMetalLayer that given by `GetCAMetalLayer` call. This is only
+  /// called when the specified render target type in `kCAMetalLayer`.
+  ///
+  /// @see |GPUSurfaceMetalDelegate::GetCAMetalLayer|
+  ///
+  virtual bool PresentDrawable(GrMTLHandle drawable) const = 0;
+
+  //------------------------------------------------------------------------------
+  /// @brief Returns the handle to the MTLTexture to render to. This is only
+  /// called when the specefied render target type is `kMTLTexture`.
+  ///
+  virtual GPUMTLTextureInfo GetMTLTexture(MTLFrameInfo frame_info) const = 0;
+
+  //------------------------------------------------------------------------------
+  /// @brief Presents the texture with `texture_id` to the "screen".
+  /// `texture_id` corresponds to a texture that has been obtained by an earlier
+  /// call to `GetMTLTexture`. This is only called when the specefied render
+  /// target type is `kMTLTexture`.
+  ///
+  /// @see |GPUSurfaceMetalDelegate::GetMTLTexture|
+  ///
+  virtual bool PresentTexture(intptr_t texture_id) const = 0;
+
+  MTLRenderTargetType GetRenderTargetType();
+
+ private:
+  const MTLRenderTargetType render_target_type_;
+};
+
+}  // namespace flutter
+
+#endif  // FLUTTER_SHELL_GPU_GPU_SURFACE_METAL_DELEGATE_H_

shell/platform/darwin/graphics/BUILD.gn

@@ -0,0 +1,26 @@
+# Copyright 2013 The Flutter Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+assert(is_ios || is_mac)
+
+import("//flutter/common/config.gni")
+
+source_set("graphics") {
+  cflags_objc = flutter_cflags_objc
+  cflags_objcc = flutter_cflags_objcc
+
+  sources = [
+    "FlutterDarwinContextMetal.h",
+    "FlutterDarwinContextMetal.mm",
+  ]
+
+  deps = [
+    "//flutter/common/graphics",
+    "//flutter/fml",
+  ]
+
+  public_deps = [ "//third_party/skia" ]
+
+  public_configs = [ "//flutter:config" ]
+}