Port cache-dir from soc/directories-jvm

Author: liquidz

CHANGELOG.md

@@ -9,6 +9,7 @@
 * [#46](https://github.com/clojure-emacs/orchard/pull/46): [Inspector] Show fields inherited from superclasses when rendering raw objects.
 * [#47](https://github.com/clojure-emacs/orchard/pull/46): [Java] Cache class-info for editable Java classes.
 * [#51](https://github.com/clojure-emacs/orchard/issues/51): Add basic xref functionality in `orchard.xref`.
+* [#64](https://github.com/clojure-emacs/orchard/issues/64): Port `cache-dir` from [soc/directories-jvm](https://github.com/soc/directories-jvm) to `orchard.directory`.
 
 ### Changes
 

src/orchard/directory.clj

@@ -0,0 +1,67 @@
+(ns orchard.directory
+  "A port of BaseDirectories.java in soc/directories-jvm.
+  https://github.com/soc/directories-jvm"
+  {:author "Masashi Iizuka"
+   :added "0.5.0"}
+  (:require [clojure.java.io :as io]
+            [clojure.string :as str]
+            [orchard.misc :as u])
+  (:import (java.io BufferedReader)))
+
+(def file-separator (System/getProperty "file.separator"))
+
+(defn- run-commands [expected-result-lines commands]
+  (let [commands ^"[Ljava.lang.String;" (into-array String commands)
+        builder (ProcessBuilder. commands)
+        process (.start builder)]
+    (with-open [reader ^BufferedReader (io/reader (.getInputStream process))]
+      (try
+        (doall (repeatedly expected-result-lines #(.readLine reader)))
+        (finally
+          (.destroy process))))))
+
+(defn- get-win-dirs [guids]
+  (let [commands (concat ["& {"
+                          "[Console]::OutputEncoding = [System.Text.Encoding]::UTF8"
+                          "Add-Type @\\\""
+                          "using System;"
+                          "using System.Runtime.InteropServices;"
+                          "public class Dir {"
+                          "   [DllImport(\\\"shell32.dll\\\")]"
+                          "   private static extern int SHGetKnownFolderPath([MarshalAs(UnmanagedType.LPStruct)] Guid rfid, uint dwFlags, IntPtr hToken, out IntPtr pszPath);"
+                          "   public static string GetKnownFolderPath(string rfid) {"
+                          "       IntPtr pszPath;"
+                          "       if (SHGetKnownFolderPath(new Guid(rfid), 0, IntPtr.Zero, out pszPath) != 0) return \\\"\\\";"
+                          "       string path = Marshal.PtrToStringUni(pszPath);"
+                          "       Marshal.FreeCoTaskMem(pszPath);"
+                          "       return path;"
+                          "   }"
+                          "}"
+                          "\\\"@"]
+                         (map #(str "[Dir]::GetKnownFolderPath(\\\"" %  "\\\")") guids)
+                         ["}"])]
+    (run-commands (count guids) ["powershell.exe" "-Command" (str/join "\n" commands)])))
+
+(defn cache-dir
+  "Returns the path to the user's cache directory.
+
+  macOS  : $HOME/Library/Caches
+  Windows: FOLDERID_LocalAppData\\cache
+  Others : $XDG_CACHE_HOME or $HOME/.cache"
+  {:added "0.5.0"}
+  []
+  (case u/os-type
+    ::u/os-mac
+    (str/join file-separator [(System/getProperty "user.home")
+                              "Library"
+                              "Caches"])
+
+    ::u/os-windows
+    (-> ["F1B32785-6FBA-4FCF-9D55-7B8E7F157091"]
+        get-win-dirs
+        first)
+
+    (let [cache-home (System/getenv "XDG_CACHE_HOME")]
+      (if (str/blank? cache-home)
+        (str (System/getProperty "user.home") file-separator ".cache")
+        cache-home))))

test/orchard/directory_test.clj

@@ -0,0 +1,24 @@
+(ns orchard.directory-test
+  (:require
+   [clojure.string :as str]
+   [clojure.test :as test :refer [deftest is testing]]
+   [orchard.directory :as dir]
+   [orchard.misc :as u]))
+
+(deftest cache-dir-test
+  (testing "BSD"
+    (with-redefs [u/os-type ::u/os-bsd]
+      (is (str/ends-with? (dir/cache-dir) "/.cache"))))
+
+  (testing "Linux"
+    (with-redefs [u/os-type ::u/os-linux]
+      (is (str/ends-with? (dir/cache-dir) "/.cache"))))
+
+  (testing "Mac"
+    (with-redefs [u/os-type ::u/os-mac]
+      (is (str/ends-with? (dir/cache-dir) "/Library/Caches")))))
+
+;; NOTE: This test case targets AppVeyor mainly
+(deftest cache-dir-windows-test
+  (when (u/os-windows?)
+    (is (re-seq #"^C:\\Users\\.+\\AppData\\Local" (dir/cache-dir)))))