Scroll buffer after using cider-insert-X-in-repl

As it stood, buffer would not scroll, even if you included a
`(goto-char (point-max))` call at the end. Using solution from
https://stackoverflow.com/questions/13530025/emacs-scroll-automatically-when-inserting-text

Have to watch out if the buffer is visible or not. If it is, we can
scroll it with `with-selected-window`. Otherwise, the best we can do
is the current behavior. Note `get-buffer-window` returns nil if
something is not visible which is why we need to branch on it.

Author: dan sutton

cider-mode.el

@@ -232,20 +232,30 @@ and eval and the prefix is required to prevent evaluation."
   :group 'cider
   :package-version '(cider . "0.18.0"))
 
+(defun cider--insert-in-repl (form eval)
+  (goto-char (point-max))
+  (let ((beg (point)))
+    (insert form)
+    (indent-region beg (point)))
+  (when (if cider-invert-insert-eval-p
+            (not eval)
+          eval)
+    (cider-repl-return))
+  (goto-char (point-max)))
+
 (defun cider-insert-in-repl (form eval)
   "Insert FORM in the REPL buffer and switch to it.
 If EVAL is non-nil the form will also be evaluated."
   (while (string-match "\\`[ \t\n\r]+\\|[ \t\n\r]+\\'" form)
     (setq form (replace-match "" t t form)))
-  (with-current-buffer (cider-current-repl)
-    (goto-char (point-max))
-    (let ((beg (point)))
-      (insert form)
-      (indent-region beg (point)))
-    (when (if cider-invert-insert-eval-p
-              (not eval)
-            eval)
-      (cider-repl-return)))
+  (let ((repl (cider-current-repl)))
+    (if-let* ((window (get-buffer-window repl)))
+        ;; if buffer is visible we can scroll it
+        (with-selected-window window
+          (cider--insert-in-repl form eval))
+      ;; if not visible, we can only insert into it
+      (with-current-buffer repl
+        (cider--insert-in-repl form eval))))
   (when cider-switch-to-repl-after-insert-p
     (cider-switch-to-repl-buffer)))