[Fix #1299] Eval in both REPLs for cljc and cljx

This changes the load file request to dispatch to
`cider-other-connection` in addition to `cider-current-connection`, when
the file is a cljc or cljx file.

Author: expez

CHANGELOG.md

@@ -48,6 +48,7 @@
 
 ### Changes
 
+* [#1299]https://github.com/clojure-emacs/cider/issues/1299 <kbd>C-c C-k</kbd> and <kbd> C-c C-l</kbd> now dispatch to both the Clojure and ClojureScript REPL (in the same project) when called from a `.cljc` or `.cljx` file.
 * [#1397](https://github.com/clojure-emacs/cider/issues/1297) <kbd>C-c M-n</kbd> now changes the ns of both the Clojure and ClojureScript REPL (in the same project) when called from a cljc or cljx file.
 * [#1348](https://github.com/clojure-emacs/cider/issues/1348): Drop the dash dependency.
 * The usage of the default connection has been reduced significantly. Now evaluations & related commands will be routed via the connection matching the current project automatically unless there's some ambiguity when determining the connection (like multiple or no matching connections). Simply put you'll no longer have to mess around much with connecting-setting commands (e.g. `nrepl-connection-browser`, `cider-rotate-default-connection`).

cider-client.el

@@ -218,9 +218,7 @@ from the file extension."
               ;; OW, find one matching the extension of current file.
               (let ((type (or type (file-name-extension (or (buffer-file-name) "")))))
                 (or (seq-find (lambda (conn)
-                                (equal (with-current-buffer conn
-                                         cider-repl-type)
-                                       type))
+                                (equal (cider--connection-type conn) type))
                               project-connections)
                     (car project-connections)))))))
     ;; TODO: Add logic to dispatch to a matching Clojure/ClojureScript REPL based on file type
@@ -422,12 +420,16 @@ Signal an error if it is not supported."
   (unless (cider-nrepl-op-supported-p op)
     (error "Can't find nREPL middleware providing op \"%s\".  Please, install (or update) cider-nrepl %s and restart CIDER" op (upcase cider-version))))
 
-(defun cider-nrepl-send-request (request callback)
+(defun cider-nrepl-send-request (request callback &optional connection)
   "Send REQUEST and register response handler CALLBACK.
 REQUEST is a pair list of the form (\"op\" \"operation\" \"par1-name\"
 \"par1\" ... ).
+
+If CONNECTION is provided dispatch to that connection instead of
+the current connection.
+
 Return the id of the sent message."
-  (nrepl-send-request request callback (cider-current-connection)))
+  (nrepl-send-request request callback (or connection (cider-current-connection))))
 
 (defun cider-nrepl-send-sync-request (request &optional abort-on-input)
   "Send REQUEST to the nREPL server synchronously.
@@ -596,17 +598,21 @@ thing at point."
 ;;; Requests
 
 (declare-function cider-load-file-handler "cider-interaction")
-(defun cider-request:load-file (file-contents file-path file-name &optional callback)
+(defun cider-request:load-file (file-contents file-path file-name &optional connection callback)
   "Perform the nREPL \"load-file\" op.
 FILE-CONTENTS, FILE-PATH and FILE-NAME are details of the file to be
-loaded. If CALLBACK is nil, use `cider-load-file-handler'."
+loaded.
+
+If CONNECTION is nil, use `cider-current-connection'.
+If CALLBACK is nil, use `cider-load-file-handler'."
   (cider-nrepl-send-request (list "op" "load-file"
                                   "session" (cider-current-session)
                                   "file" file-contents
                                   "file-path" file-path
                                   "file-name" file-name)
                             (or callback
-                                (cider-load-file-handler (current-buffer)))))
+                                (cider-load-file-handler (current-buffer)))
+                            connection))
 
 
 ;;; Sync Requests

cider-common.el

@@ -224,5 +224,20 @@ existing file ending with URL has been found."
       (16 t) ; empty empty
       (_ nil))))
 
+(defmacro cider-do-connections (var &rest body)
+  "For each appropriate connection, bind it to VAR, and execute BODY.
+
+The appropriate connections are found by inspecting the current buffer.  If
+the buffer is associated with a .cljc or .cljx file, BODY will be executed
+multiple times."
+  (declare (indent 1))
+  (let ((other-connection (gensym)))
+    `(if-let ((_ (cider--cljc-or-cljx-buffer-p))
+              (,other-connection (cider-other-connection)))
+         (dolist (,var (list (cider-current-connection) ,other-connection))
+           ,@body)
+       (let ((,var (cider-current-connection)))
+         ,@body))))
+
 (provide 'cider-common)
 ;;; cider-common.el ends here

cider-interaction.el

@@ -1342,32 +1342,15 @@ unloaded."
   (with-current-buffer (find-file-noselect file)
     (substring-no-properties (buffer-string))))
 
-(defun cider-load-file (filename)
-  "Load (eval) the Clojure file FILENAME in nREPL."
-  (interactive (list
-                (read-file-name "Load file: " nil nil nil
-                                (when (buffer-file-name)
-                                  (file-name-nondirectory
-                                   (buffer-file-name))))))
-  (cider-ensure-connected)
-  (when-let ((buf (find-buffer-visiting filename)))
-    (with-current-buffer buf
-      (remove-overlays nil nil 'cider-type 'instrumented-defs)
-      (cider--clear-compilation-highlights)))
-  (cider--quit-error-window)
-  (cider--cache-ns-form)
-  (cider-request:load-file
-   (cider-file-string filename)
-   (funcall cider-to-nrepl-filename-function (cider--server-filename filename))
-   (file-name-nondirectory filename))
-  (message "Loading %s..." filename))
-
 (defun cider-load-buffer (&optional buffer)
   "Load (eval) BUFFER's file in nREPL.
 If no buffer is provided the command acts on the current buffer.
-The heavy lifting is done by `cider-load-file'."
+
+If the buffer is for a cljc or cljx file, and both a Clojure and
+ClojureScript REPL exists for the project, it is evaluated in both REPLs."
   (interactive)
   (check-parens)
+  (cider-ensure-connected)
   (setq buffer (or buffer (current-buffer)))
   (with-current-buffer buffer
     (unless buffer-file-name
@@ -1377,7 +1360,33 @@ The heavy lifting is done by `cider-load-file'."
                (or (eq cider-prompt-save-file-on-load 'always-save)
                    (y-or-n-p (format "Save file %s? " buffer-file-name))))
       (save-buffer))
-    (cider-load-file buffer-file-name)))
+    (remove-overlays nil nil 'cider-type 'instrumented-defs)
+    (cider--clear-compilation-highlights)
+    (cider--quit-error-window)
+    (cider--cache-ns-form)
+    (let ((filename (buffer-file-name)))
+      (cider-do-connections connection
+        (cider-request:load-file
+         (cider-file-string filename)
+         (funcall cider-to-nrepl-filename-function (cider--server-filename filename))
+         (file-name-nondirectory filename)
+         connection))
+      (message "Loading %s..." filename))))
+
+(defun cider-load-file (filename)
+  "Load (eval) the Clojure file FILENAME in nREPL.
+
+If the file is a cljc or cljx file, and both a Clojure and ClojureScript
+REPL exists for the project, it is evaluated in both REPLs.
+
+The heavy lifting is done by `cider-load-buffer'."
+  (interactive (list
+                (read-file-name "Load file: " nil nil nil
+                                (when (buffer-file-name)
+                                  (file-name-nondirectory
+                                   (buffer-file-name))))))
+  (when-let ((buffer (find-buffer-visiting filename)))
+    (cider-load-buffer buffer)))
 
 (defalias 'cider-eval-file 'cider-load-file
   "A convenience alias as some people are confused by the load-* names.")

cider-util.el

@@ -87,6 +87,10 @@ If BUFFER is provided act on that buffer instead."
   (with-current-buffer (or buffer (current-buffer))
     (or (derived-mode-p 'clojurec-mode) (derived-mode-p 'clojurex-mode))))
 
+(defun cider--cljc-or-cljx-file-p (file-name)
+  "Return true if FILE-NAME is for a cljc or cljx file."
+  (string-match "\\.clj\\(x\\|c\\)\\'" file-name))
+
 
 ;;; Thing at point
 (defun cider-defun-at-point ()