[#12] Multi-segment namespace

Author: borkdude

.gitignore

@@ -6,3 +6,4 @@ lib
 pom.xml
 pom.xml.asc
 target
+/.cpcache

README.md

@@ -1,23 +1,23 @@
-# digest
+# clj-commons/digest
 
 [![Clojars Project](https://img.shields.io/clojars/v/org.clj-commons/digest.svg)](https://clojars.org/org.clj-commons/digest) 
 [![cljdoc badge](https://cljdoc.org/badge/org.clj-commons/digest)](https://cljdoc.org/d/org.clj-commons/digest)
 [![CircleCI Status](https://circleci.com/gh/clj-commons/clj-digest.svg?style=svg)](https://circleci.com/gh/clj-commons/clj-digest)
 
-`digest` - Message digest library for Clojure. Providing md5, sha-256, ...
+`clj-commons/digest` - A message digest library for Clojure. Providing md5, sha-256, ...
 
 There are several digest functions (such as `md5`, `sha-256` ...) in this
 namespace. Each can handle the following input types:
 
-* java.lang.String
-* byte array
-* java.io.File
-* java.io.InputStream
+* `java.lang.String`
+* `byte array`
+* `java.io.File`
+* `java.io.InputStream`
 * Sequence of byte array
 
 # Usage
 
-    user=> (require 'digest)
+    user=> (require '[clj-commons.digest :as digest])
     nil
     ; On a string
     user=> (digest/md5 "clojure")
@@ -28,8 +28,13 @@ namespace. Each can handle the following input types:
     user=> (digest/sha-256 (as-file "/tmp/hello.txt"))
     "163883d3e0e3b0c028d35b626b98564be8d9d649ed8adb8b929cb8c94c735c59"
 
+# Deprecation
+
+The single-segment `digest` namespace is deprecated since `1.4.10+`. Use
+`clj-commons.digest` instead.
+
 # Installation
-Add `[digest "1.4.10"]` to your `project.clj`.
+Add `[org.clojars/digest "1.4.10"]` to your `project.clj`.
 
 # License
 Copyright&copy; 2017 Miki Tebeka <[email protected]>

src/clj_commons/digest.clj

@@ -0,0 +1,108 @@
+(ns
+  ^{:author "Miki Tebeka <[email protected]>"
+    :doc    "Message digest algorithms for Clojure"}
+  clj-commons.digest
+  (:require [clojure.string :refer [join lower-case split]])
+  (:import (java.io File FileInputStream InputStream)
+           (java.security MessageDigest Provider Security)
+           (java.util Arrays)))
+
+; Default buffer size for reading
+(def ^:dynamic *buffer-size* 1024)
+
+(defn- read-some
+  "Read some data from reader. Return [data size] if there's more to read,
+  otherwise nil."
+  [^InputStream reader]
+  (let [^bytes buffer (make-array Byte/TYPE *buffer-size*)
+        size (.read reader buffer)]
+    (when (pos? size)
+      (if (= size *buffer-size*) buffer (Arrays/copyOf buffer size)))))
+
+(defn- byte-seq
+  "Return a sequence of [data size] from reader."
+  [^InputStream reader]
+  (take-while some? (repeatedly (partial read-some reader))))
+
+(defn- signature
+  "Get signature (string) of digest."
+  [^MessageDigest algorithm]
+  (let [size (* 2 (.getDigestLength algorithm))
+        sig (.toString (BigInteger. 1 (.digest algorithm)) 16)
+        padding (join (repeat (- size (count sig)) "0"))]
+    (str padding sig)))
+
+(defprotocol Digestible
+  (-digest [message algorithm]))
+
+(extend-protocol Digestible
+  (class (make-array Byte/TYPE 0))
+  (-digest [message algorithm]
+    (-digest [message] algorithm))
+
+  java.util.Collection
+  ;; Code "borrowed" from
+  ;; * http://www.holygoat.co.uk/blog/entry/2009-03-26-1
+  ;; * http://www.rgagnon.com/javadetails/java-0416.html
+  (-digest [message algorithm]
+    (let [^MessageDigest algo (MessageDigest/getInstance algorithm)]
+      (.reset algo)
+      (doseq [^bytes b message] (.update algo b))
+      (signature algo)))
+
+  String
+  (-digest [message algorithm]
+    (-digest [(.getBytes message)] algorithm))
+
+  InputStream
+  (-digest [reader algorithm]
+    (-digest (byte-seq reader) algorithm))
+
+  File
+  (-digest [file algorithm]
+    (with-open [f (FileInputStream. file)]
+      (-digest f algorithm)))
+
+  nil
+  (-digest [message algorithm]
+    nil))
+
+(defn digest
+  "Returns digest for message with given algorithm."
+  [algorithm message]
+  (-digest message algorithm))
+
+(defn algorithms
+  "List supported digest algorithms."
+  []
+  (let [providers (vec (Security/getProviders))
+        names (mapcat (fn [^Provider p] (enumeration-seq (.keys p))) providers)
+        digest-names (filter #(re-find #"MessageDigest\.[A-Z0-9-]+$" %) names)]
+    (set (map #(last (split % #"\.")) digest-names))))
+
+(defn- create-fn!
+  [algorithm-name]
+  (let [update-meta (fn [meta]
+                      (assoc meta
+                             :doc (str "Encode the given message with the " algorithm-name " algorithm.")
+                             :arglists '([message])))]
+    (-> (intern *ns*
+                (symbol (lower-case algorithm-name))
+                (partial digest algorithm-name))
+        (alter-meta! update-meta))))
+
+(defn- create-fns
+  "Create utility function for each digest algorithms.
+   For example will create an md5 function for MD5 algorithm."
+  []
+  (doseq [algorithm (algorithms)]
+    (create-fn! algorithm)))
+
+; Create utility functions such as md5, sha-256 ...
+(create-fns)
+
+;;;; Hints for clj-kondo
+
+(comment
+  (declare sha3-384 sha-256 sha3-256 sha-384 sha3-512 sha-1 sha-224 sha1 sha-512 md2 sha sha3-224 md5)
+  )

src/digest.clj

@@ -1,6 +1,8 @@
 (ns
   ^{:author "Miki Tebeka <[email protected]>"
-    :doc    "Message digest algorithms for Clojure"}
+    :doc    "Message digest algorithms for Clojure"
+    ;; single segment namespace is deprecated, use clj-commons/digest
+    :deprecated true}
   digest
   (:require [clojure.string :refer [join lower-case split]])
   (:import (java.io File FileInputStream InputStream)

test/clj_commons/digest_test.clj

@@ -0,0 +1,44 @@
+(ns clj-commons.digest-test
+  (:require [clj-commons.digest :as d]
+            [clojure.string :refer [lower-case includes?]]
+            [clojure.test :refer [deftest is]])
+  (:import java.io.File))
+
+(deftest md5-test
+  (is (= (d/digest "md5" "clojure") "32c0d97f82a20e67c6d184620f6bd322")))
+
+(deftest sha-256-test
+  (is (= (d/sha-256 "clojure")
+         "4f3ea34e0a3a6196a18ec24b51c02b41d5f15bd04b4a94aa29e4f6badba0f5b0")))
+
+(deftest algorithms-test
+  (let [names (d/algorithms)]
+    (is (seq names))
+    (is (names "SHA-1"))))
+
+(deftest utils-test
+  (for [name (d/algorithms)]
+    (dorun (is (ns-resolve *ns* (symbol (lower-case name)))))))
+
+(deftest function-metadata-test
+  (is (includes? (:doc (meta #'d/sha-256))
+                 "SHA-256"))
+  (is (= '([message])
+         (:arglists (meta #'d/md5)))))
+
+(def ^:dynamic *image-md5* "49c39580caf91363e4a4cacfa5564489")
+(def ^:dynamic *image-sha1*
+  "96f2328cf279b95ddb1dee36df0c91cd7821e741")
+
+(deftest file-test
+  (let [f (File. "test/snail.png")]
+    (is (= (d/md5 f) *image-md5*))
+    (is (= (d/sha-1 f) *image-sha1*))))
+
+; Just making sure that we don't explode on nil
+(deftest nil-test
+  (d/md5 nil))
+
+(deftest length-test
+  (is (= (d/sha (File. "test/quote.txt"))
+         "dc93ad3c1e212bf598b9bf700914e832c9bdade5")))