Fix module-info generation for multiplatform artifact

Author: serjsysoev

multiplatform-annotations/build.gradle.kts

@@ -1,4 +1,5 @@
 import org.gradle.jvm.tasks.Jar
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
 
 plugins {
     kotlin("multiplatform") version "1.9.22"
@@ -75,19 +76,56 @@ kotlin {
     }
 }
 
-val jvmJar by tasks.getting(Jar::class) {
-    into ("META-INF/versions/9") {
-        from (project(":multiplatform-module-info").sourceSets["main"].output) {
-            include("module-info.class")
-        }
+// from https://github.com/Kotlin/kotlinx-datetime/blob/bc8adee2b9e3659e8e1c38fc09f3a4a1bdf85276/core/build.gradle.kts
+tasks {
+    val compileJavaModuleInfo by registering(JavaCompile::class) {
+        val moduleName = "org.jetbrains.annotations.multiplatform" // this module's name
+        val compileKotlinJvm by getting(KotlinCompile::class)
+        val sourceDir = file("src/jvmMain/moduleInfo/")
+        println("sourceDir: $sourceDir")
+        val targetDir = compileKotlinJvm.destinationDirectory.map { it.dir("../moduleInfo/") }
+        println("targetDir: $targetDir")
+
+        // Use a Java 11 compiler for the module info.
+        javaCompiler.set(project.javaToolchains.compilerFor { languageVersion.set(JavaLanguageVersion.of(11)) })
+
+        // Always compile kotlin classes before the module descriptor.
+        dependsOn(compileKotlinJvm)
+
+        // Add the module-info source file.
+        source(sourceDir)
+
+        // Set the task outputs and destination dir
+        outputs.dir(targetDir)
+        destinationDirectory.set(targetDir)
+
+        // Configure JVM compatibility
+        sourceCompatibility = JavaVersion.VERSION_1_9.toString()
+        targetCompatibility = JavaVersion.VERSION_1_9.toString()
+
+        // Set the Java release version.
+        options.release.set(9)
+
+        // Ignore warnings about using 'requires transitive' on automatic modules.
+        // not needed when compiling with recent JDKs, e.g. 17
+        options.compilerArgs.add("-Xlint:-requires-transitive-automatic")
+
+        // Patch the compileKotlinJvm output classes into the compilation so exporting packages works correctly.
+        options.compilerArgs.addAll(listOf("--patch-module", "$moduleName=${compileKotlinJvm.destinationDirectory.get()}"))
+
+        // Use the classpath of the compileKotlinJvm task.
+        // Also ensure that the module path is used instead of classpath.
+        classpath = compileKotlinJvm.libraries
+        modularity.inferModulePath.set(true)
     }
-    manifest.attributes("Multi-Release" to true)
-}
 
-val jvmSourcesJar by tasks.getting(Jar::class) {
-    into ("META-INF/versions/9") {
-        from (project(":multiplatform-module-info").sourceSets["main"].output) {
-            include("module-info.class")
+    // Configure the JAR task so that it will include the compiled module-info class file.
+    val jvmJar by existing(Jar::class) {
+        manifest {
+            attributes("Multi-Release" to true)
+        }
+        from(compileJavaModuleInfo.map { it.destinationDirectory }) {
+            into("META-INF/versions/9/")
         }
     }
 }

multiplatform-module-info/src/main/java/module-info.java renamed to multiplatform-annotations/src/jvmMain/moduleInfo/module-info.java

@@ -16,4 +16,4 @@
 
 rootProject.name = 'annotations-parent'
 
-include 'java-annotations', 'java-module-info', 'multiplatform-annotations', 'multiplatform-module-info'
+include 'java-annotations', 'java-module-info', 'multiplatform-annotations'