Merge pull request elixir-editors#50 from mattbaker/reference-support

Reference support

Author: JakeBecker

apps/language_server/lib/language_server/protocol.ex

@@ -64,6 +64,16 @@ defmodule ElixirLS.LanguageServer.Protocol do
     end
   end
 
+  defmacro references_req(id, uri, line, character, include_declaration) do
+    quote do
+      request(unquote(id), "textDocument/references", %{
+        "textDocument" => %{"uri" => unquote(uri)},
+        "position" => %{"line" => unquote(line), "character" => unquote(character)},
+        "context" => %{"includeDeclaration" => unquote(include_declaration)}
+      })
+    end
+  end
+
   defmacro initialize_req(id, root_uri, client_capabilities) do
     quote do
       request(unquote(id), "initialize", %{

apps/language_server/lib/language_server/providers/references.ex

@@ -0,0 +1,67 @@
+defmodule ElixirLS.LanguageServer.Providers.References do
+  @moduledoc """
+  This module provides References support by using
+  the `Mix.Tasks.Xref.call/0` task to find all references to
+  any function or module identified at the provided location.
+  """
+
+  alias ElixirLS.LanguageServer.SourceFile
+  alias ElixirSense.Core.{Metadata, Parser, Source, Introspection}
+
+  def references(text, line, character, _include_declaration) do
+    xref_at_cursor(text, line, character)
+    |> Enum.filter(fn %{line: line} -> is_integer(line) end)
+    |> Enum.map(&build_location/1)
+  end
+
+  def supported? do
+    Mix.Tasks.Xref.__info__(:functions) |> Enum.member?({:calls, 0})
+  end
+
+  defp xref_at_cursor(text, line, character) do
+    env_at_cursor = line_environment(text, line)
+
+    subject_at_cursor(text, line, character)
+    |> Introspection.split_mod_fun_call()
+    |> expand_mod_fun(env_at_cursor)
+    |> add_arity(env_at_cursor)
+    |> callers()
+  end
+
+  defp line_environment(text, line) do
+    Parser.parse_string(text, true, true, line + 1) |> Metadata.get_env(line + 1)
+  end
+
+  defp subject_at_cursor(text, line, character) do
+    Source.subject(text, line + 1, character + 1)
+  end
+
+  defp expand_mod_fun({nil, nil}, _environment), do: nil
+
+  defp expand_mod_fun(mod_fun, %{imports: imports, aliases: aliases, module: module}) do
+    case Introspection.actual_mod_fun(mod_fun, imports, aliases, module) do
+      {mod, nil} -> {mod, nil}
+      {mod, fun} -> {mod, fun}
+    end
+  end
+
+  defp add_arity({mod, fun}, %{scope: {fun, arity}, module: mod}), do: {mod, fun, arity}
+  defp add_arity({mod, fun}, _env), do: {mod, fun, nil}
+
+  def callers(nil), do: []
+  def callers(mfa), do: Mix.Tasks.Xref.calls() |> Enum.filter(caller_filter(mfa))
+
+  defp caller_filter({module, nil, nil}), do: &match?(%{callee: {^module, _, _}}, &1)
+  defp caller_filter({module, func, nil}), do: &match?(%{callee: {^module, ^func, _}}, &1)
+  defp caller_filter({module, func, arity}), do: &match?(%{callee: {^module, ^func, ^arity}}, &1)
+
+  defp build_location(call) do
+    %{
+      "uri" => SourceFile.path_to_uri(call.file),
+      "range" => %{
+        "start" => %{"line" => call.line - 1, "character" => 0},
+        "end" => %{"line" => call.line - 1, "character" => 0}
+      }
+    }
+  end
+end

apps/language_server/lib/language_server/server.ex

@@ -23,6 +23,7 @@ defmodule ElixirLS.LanguageServer.Server do
     Completion,
     Hover,
     Definition,
+    References,
     Formatting,
     SignatureHelp
   }
@@ -322,6 +323,17 @@ defmodule ElixirLS.LanguageServer.Server do
     {:async, fun, state}
   end
 
+  defp handle_request(references_req(_id, uri, line, character, include_declaration), state) do
+    fun = fn ->
+      {
+        :ok,
+        References.references(state.source_files[uri].text, line, character, include_declaration)
+      }
+    end
+
+    {:async, fun, state}
+  end
+
   defp handle_request(hover_req(_id, uri, line, character), state) do
     fun = fn ->
       Hover.hover(state.source_files[uri].text, line, character)
@@ -391,6 +403,7 @@ defmodule ElixirLS.LanguageServer.Server do
       "hoverProvider" => true,
       "completionProvider" => %{"triggerCharacters" => ["."]},
       "definitionProvider" => true,
+      "referencesProvider" => References.supported?(),
       "documentFormattingProvider" => Formatting.supported?(),
       "signatureHelpProvider" => %{"triggerCharacters" => ["("]}
     }