Initial release

Author: ArduinoGetStarted

README.md

@@ -0,0 +1,21 @@
+## Button Library for Arduino
+This library is designed for push button, momentary switches. It is easy to use for not only beginners but also experienced users.
+
+Features
+----------------------------
+* Uses the internal pull-up resistor to avoid the floating value
+* Supports debounce to eliminate the chattering phenomenon
+* Supports the pressed and released events
+* Easy to use with multiple buttons
+
+Available Examples
+----------------------------
+* 01.SingleButton
+* 02.SingleButtonDebounce
+* 03.SingleButtonEvents
+* 04.SingleButtonAll
+* 05.MultipleButtonAll
+
+References
+----------------------------
+* [Button Library Reference](https://arduinogetstarted.com/tutorials/arduino-button-library)

examples/01.SingleButton/01.SingleButton.ino

@@ -0,0 +1,24 @@
+/*
+ * Created by ArduinoGetStarted.com
+ *
+ * This example code is in the public domain
+ *
+ * Tutorial page: https://arduinogetstarted.com/tutorials/arduino-button-library
+ *
+ * This example reads the state of a button without debounce and print it to Serial Monitor.
+ */
+
+#include <Button.h>
+
+Button button(7);  // create Button object that attach to pin 7;
+
+void setup() {
+  Serial.begin(9600);
+}
+
+void loop() {
+  button.loop(); // MUST call the loop() function first
+
+  int btnState = button.getState();
+  Serial.println(btnState);
+}

examples/02.SingleButtonDebounce/02.SingleButtonDebounce.ino

@@ -0,0 +1,25 @@
+/*
+ * Created by ArduinoGetStarted.com
+ *
+ * This example code is in the public domain
+ *
+ * Tutorial page: https://arduinogetstarted.com/tutorials/arduino-button-library
+ *
+ * This example reads the state if a button with debounce and print it to Serial Monitor.
+ */
+
+#include <Button.h>
+
+Button button(7);  // create Button object that attach to pin 7;
+
+void setup() {
+  Serial.begin(9600);
+  button.setDebounceTime(100); // set debounce time to 100 milliseconds
+}
+
+void loop() {
+  button.loop(); // MUST call the loop() function first
+
+  int btnState = button.getState();
+  Serial.println(btnState);
+}

examples/03.SingleButtonEvents/03.SingleButtonEvents.ino

@@ -0,0 +1,27 @@
+/*
+ * Created by ArduinoGetStarted.com
+ *
+ * This example code is in the public domain
+ *
+ * Tutorial page: https://arduinogetstarted.com/tutorials/arduino-button-library
+ *
+ * This example detects the pressed and released events of a button without debounce.
+ */
+
+#include <Button.h>
+
+Button button(7);  // create Button object that attach to pin 7;
+
+void setup() {
+  Serial.begin(9600);
+}
+
+void loop() {
+  button.loop(); // MUST call the loop() function first
+
+  if(button.isPressed())
+    Serial.println("The button is pressed");
+
+  if(button.isReleased())
+    Serial.println("The button is released");
+}

examples/04.SingleButtonAll/04.SingleButtonAll.ino

@@ -0,0 +1,34 @@
+/*
+ * Created by ArduinoGetStarted.com
+ *
+ * This example code is in the public domain
+ *
+ * Tutorial page: https://arduinogetstarted.com/tutorials/arduino-button-library
+ *
+ * This example:
+ *   + uses debounce for a button.
+ *   + reads state of a button
+ *   + detects the pressed and released events of a button
+ */
+
+#include <Button.h>
+
+Button button(7);  // create Button object that attach to pin 7;
+
+void setup() {
+  Serial.begin(9600);
+  button.setDebounceTime(100); // set debounce time to 100 milliseconds
+}
+
+void loop() {
+  button.loop(); // MUST call the loop() function first
+
+  int btnState = button.getState();
+  Serial.println(btnState);
+
+  if(button.isPressed())
+    Serial.println("The button is pressed");
+
+  if(button.isReleased())
+    Serial.println("The button is released");
+}

examples/05.MultipleButtonAll/05.MultipleButtonAll.ino

@@ -0,0 +1,47 @@
+/*
+ * Created by ArduinoGetStarted.com
+ *
+ * This example code is in the public domain
+ *
+ * Tutorial page: https://arduinogetstarted.com/tutorials/arduino-button-library
+ *
+ * This example:
+ *   + uses debounce for multiple buttons.
+ *   + reads state of multiple buttons
+ *   + detects the pressed and released events of multiple buttons
+ */
+
+#include <Button.h>
+
+Button button1(6);  // create Button object that attach to pin 6;
+Button button2(7);  // create Button object that attach to pin 7;
+
+void setup() {
+  Serial.begin(9600);
+  button1.setDebounceTime(100); // set debounce time to 100 milliseconds
+  button2.setDebounceTime(100); // set debounce time to 100 milliseconds
+}
+
+void loop() {
+  button1.loop(); // MUST call the loop() function first
+  button2.loop(); // MUST call the loop() function first
+
+  int btn1State = button1.getState();
+  int btn2State = button2.getState();
+  Serial.print("button 1 state: ");
+  Serial.println(btn1State);
+  Serial.print("button 2 state: ");
+  Serial.println(btn2State);
+
+  if(button1.isPressed())
+    Serial.println("The button 1 is pressed");
+
+  if(button1.isReleased())
+    Serial.println("The button 1 is released");
+
+  if(button2.isPressed())
+    Serial.println("The button 2 is pressed");
+
+  if(button2.isReleased())
+    Serial.println("The button 2 is released");
+}

keywords.txt

@@ -0,0 +1,25 @@
+#######################################
+# Syntax Coloring Map For Button
+#######################################
+
+#######################################
+# Datatypes (KEYWORD1)
+#######################################
+
+Button	KEYWORD1
+button	KEYWORD1
+
+#######################################
+# Methods and Functions (KEYWORD2)
+#######################################
+
+setDebounceTime	KEYWORD2
+getState	KEYWORD2
+getStateRaw	KEYWORD2
+isPressed	KEYWORD2
+isReleased	KEYWORD2
+
+
+#######################################
+# Constants (LITERAL1)
+#######################################

library.properties

@@ -0,0 +1,10 @@
+name=ezButton
+version=1.0.0
+author=ArduinoGetStarted.com
+maintainer=ArduinoGetStarted.com ([email protected])
+sentence=Button library for Arduino
+paragraph=Button library supports debounce, pressed/released events. It is easy to use with multiple buttons. It is designed for not only beginners but also experienced users
+category=Signal Input/Output
+url=https://arduinogetstarted.com/tutorials/arduino-button-library
+architectures=avr
+includes=Button.h

src/Button.cpp

@@ -0,0 +1,94 @@
+/*
+ * Copyright (c) 2019, ArduinoGetStarted.com. All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ *
+ * - Redistributions of source code must retain the above copyright
+ *   notice, this list of conditions and the following disclaimer.
+ *
+ * - Redistributions in binary form must reproduce the above copyright
+ *   notice, this list of conditions and the following disclaimer in the
+ *   documentation and/or other materials provided with the distribution.
+ *
+ * - Neither the name of the ArduinoGetStarted.com nor the names of its
+ *   contributors may be used to endorse or promote products derived from
+ *   this software without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY ARDUINOGETSTARTED.COM "AS IS" AND ANY EXPRESS OR
+ * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+ * DISCLAIMED. IN NO EVENT SHALL ARDUINOGETSTARTED.COM BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+ * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+ * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
+ * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
+ * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#include <Button.h>
+
+Button::Button(int pin) {
+	btnPin = pin;
+	debounceTime = 0;
+
+	pinMode(btnPin, INPUT_PULLUP);
+
+	previousSteadyState = digitalRead(btnPin);
+	lastSteadyState = digitalRead(btnPin);
+	lastFlickerableState = digitalRead(btnPin);
+}
+
+void Button::setDebounceTime(unsigned long time) {
+	debounceTime = time;
+}
+
+int Button::getState(void) {
+	return lastSteadyState;
+}
+
+int Button::getStateRaw(void) {
+	return digitalRead(btnPin);
+}
+bool Button::isPressed(void) {
+	if(previousSteadyState == HIGH && lastSteadyState == LOW)
+		return true;
+	else
+		return false;
+}
+bool Button::isReleased(void) {
+	if(previousSteadyState == LOW && lastSteadyState == HIGH)
+		return true;
+	else
+		return false;
+}
+
+void Button::loop() {
+	// read the state of the switch/button:
+	currentState = digitalRead(btnPin);
+
+	// check to see if you just pressed the button
+	// (i.e. the input went from LOW to HIGH), and you've waited long enough
+	// since the last press to ignore any noise:
+
+	// If the switch/button changed, due to noise or pressing:
+	if (currentState != lastFlickerableState) {
+		// reset the debouncing timer
+		lastDebounceTime = millis();
+		// save the the last flickerable state
+		lastFlickerableState = currentState;
+	}
+
+	if ((millis() - lastDebounceTime) >= debounceTime) {
+		// whatever the reading is at, it's been there for longer than the debounce
+		// delay, so take it as the actual current state:
+
+		// save the the steady state
+		previousSteadyState = lastSteadyState;
+		lastSteadyState = currentState;
+	}
+}
+

src/Button.h

@@ -0,0 +1,60 @@
+/*
+ * Copyright (c) 2019, ArduinoGetStarted.com. All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ *
+ * - Redistributions of source code must retain the above copyright
+ *   notice, this list of conditions and the following disclaimer.
+ *
+ * - Redistributions in binary form must reproduce the above copyright
+ *   notice, this list of conditions and the following disclaimer in the
+ *   documentation and/or other materials provided with the distribution.
+ *
+ * - Neither the name of the ArduinoGetStarted.com nor the names of its
+ *   contributors may be used to endorse or promote products derived from
+ *   this software without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY ARDUINOGETSTARTED.COM "AS IS" AND ANY EXPRESS OR
+ * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+ * DISCLAIMED. IN NO EVENT SHALL ARDUINOGETSTARTED.COM BE LIABLE FOR ANY DIRECT,
+ * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+ * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+ * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
+ * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
+ * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#ifndef Button_h
+#define Button_h
+
+#include <Arduino.h>
+
+class Button
+{
+	private:
+		int btnPin;
+		unsigned long debounceTime;
+
+		int previousSteadyState;  // the previous steady state from the input pin, used to detect pressed and released event
+		int lastSteadyState;      // the last steady state from the input pin
+		int lastFlickerableState; // the last flickerable state from the input pin
+		int currentState;         // the current reading from the input pin
+
+		unsigned long lastDebounceTime = 0; // the last time the output pin was toggled
+
+	public:
+		Button(int pin);
+		void setDebounceTime(unsigned long time);
+		int getState(void);
+		int getStateRaw(void);
+		bool isPressed(void);
+		bool isReleased(void);
+		void loop();
+};
+
+#endif