Add new StrMaxSequenceLength routine & unit test

Added the new function to the UStrUtils unit.

Added unit test for the function to Tests/Src/DUnit/TestUStrUtils unit.

Author: delphidabbler

Src/UStrUtils.pas

@@ -289,6 +289,15 @@ function StrOfChar(const Ch: Char; const Count: Word): string;
 ///  <remarks>If Count is zero then an empty string is returned.</remarks>
 function StrOfSpaces(const Count: Word): string;
 
+///  <summary>Returns the length of the longest repeating sequence of a given
+///  character in a given string.</summary>
+///  <param name="Ch"><c>Char</c> [in] Character to search for.</param>
+///  <param name="S"><c>string</c> [in] String to search within.</param>
+///  <returns><c>Cardinal</c>. Length of the longest sequence of <c>Ch</c> in
+///  <c>S</c>, or <c>0</c> if <c>Ch</c> is not in <c>S</c>.</returns>
+function StrMaxSequenceLength(const Ch: Char; const S: UnicodeString): Cardinal;
+
+
 implementation
 
 
@@ -944,5 +953,28 @@ function StrOfSpaces(const Count: Word): string;
   Result := StrOfChar(' ', Count);
 end;
 
+function StrMaxSequenceLength(const Ch: Char; const S: UnicodeString): Cardinal;
+var
+  StartPos: Integer;
+  Count: Cardinal;
+  Idx: Integer;
+begin
+  Result := 0;
+  StartPos := StrPos(Ch, S);
+  while StartPos > 0 do
+  begin
+    Count := 1;
+    Idx := StartPos + 1;
+    while (Idx <= Length(S)) and (S[Idx] = Ch) do
+    begin
+      Inc(Idx);
+      Inc(Count);
+    end;
+    if Count > Result then
+      Result := Count;
+    StartPos := StrPos(Ch, S, Idx);
+  end;
+end;
+
 end.
 

Tests/Src/DUnit/TestUStrUtils.pas

@@ -70,6 +70,8 @@   TTestStrUtilsRoutines = class(TTestCase)
     procedure TestStrMakeSentence;
     procedure TestStrIf;
     procedure TestStrBackslashEscape;
+    procedure TestStrMaxSequenceLength;
+
   end;
 
 
@@ -672,6 +674,22 @@ procedure TTestStrUtilsRoutines.TestStrMatchText;
   );
 end;
 
+procedure TTestStrUtilsRoutines.TestStrMaxSequenceLength;
+begin
+  CheckEquals(0, StrMaxSequenceLength('~', ''), 'Test 1');
+  CheckEquals(0, StrMaxSequenceLength('~', 'freda'), 'Test 2');
+  CheckEquals(1, StrMaxSequenceLength('~', 'fre~da'), 'Test 3');
+  CheckEquals(1, StrMaxSequenceLength('|', '|fre~da'), 'Test 4');
+  CheckEquals(1, StrMaxSequenceLength('|', 'fre~da|'), 'Test 5');
+  CheckEquals(3, StrMaxSequenceLength('|', '|fre||da|||'), 'Test 6');
+  CheckEquals(3, StrMaxSequenceLength('|', '|||fre||da|||'), 'Test 7');
+  CheckEquals(4, StrMaxSequenceLength('|', '|||fre||||da|||'), 'Test 8');
+  CheckEquals(4, StrMaxSequenceLength('|', '|||f||re||||da|||'), 'Test 9');
+  CheckEquals(10, StrMaxSequenceLength('|', '||||||||||'), 'Test 10');
+  CheckEquals(1, StrMaxSequenceLength('|', '|'), 'Test 11');
+  CheckEquals(0, StrMaxSequenceLength('~', 'x'), 'Test 12');
+end;
+
 procedure TTestStrUtilsRoutines.TestStrPos_overload1;
 begin
   CheckEquals(0, StrPos('Fo', 'Bar'), 'Test 1');