Support Namespaces on search everywhere (Shift + shift).

Fixes #64

Author: ericdallo

CHANGELOG.md

@@ -3,6 +3,7 @@
 ## [Unreleased]
 
 - Bump clj4intellij to 0.7.1
+- Support Namespaces on search everywhere (Shift + shift). #64
 
 ## 3.1.1
 

src/main/clojure/com/github/clojure_lsp/intellij/client.clj

@@ -14,37 +14,52 @@
     Position
     ReferenceContext
     ReferenceParams
-    TextDocumentIdentifier]))
+    TextDocumentIdentifier
+    WorkspaceSymbolParams]
+   [org.eclipse.lsp4j.jsonrpc.messages Either]))
 
 (set! *warn-on-reflection* true)
 
+(defn project->ls-server-item ^LanguageServerItem
+  [^Project project]
+  (when-let [manager (LanguageServerManager/getInstance project)]
+    @(.getLanguageServer manager "clojure-lsp")))
+
+(defn ^:private project->ls-server ^ClojureLanguageServer [project]
+  (when-let [item (project->ls-server-item project)]
+    (.getServer item)))
+
 (defn server-status [^Project project]
   (when-let [manager (LanguageServerManager/getInstance project)]
     (keyword (.toString (.getServerStatus manager "clojure-lsp")))))
 
 (defn server-info [^Project project]
   (when (identical? :started (lsp-client/server-status project))
-    (when-let [manager (LanguageServerManager/getInstance project)]
-      (when-let [server (.getServer ^LanguageServerItem @(.getLanguageServer manager "clojure-lsp"))]
-        (some->> (.serverInfo ^ClojureLanguageServer server)
-                 deref
-                 (into {})
-                 walk/keywordize-keys)))))
+    (when-let [server (project->ls-server project)]
+      (some->> (.serverInfo ^ClojureLanguageServer server)
+               deref
+               (into {})
+               walk/keywordize-keys))))
 
 (defn dependency-contents [^String uri ^Project project]
-  (when-let [manager (LanguageServerManager/getInstance project)]
-    (when-let [server (.getServer ^LanguageServerItem @(.getLanguageServer manager "clojure-lsp"))]
-      (some->> (.dependencyContents ^ClojureLanguageServer server {"uri" uri})
-               deref))))
+  (when-let [server (project->ls-server project)]
+    (some->> (.dependencyContents ^ClojureLanguageServer server {"uri" uri})
+             deref)))
 
 (defn references [^String uri line character ^Project project]
-  (when-let [manager (LanguageServerManager/getInstance project)]
-    (when-let [server (.getServer ^LanguageServerItem @(.getLanguageServer manager "clojure-lsp"))]
-      (some-> (.getTextDocumentService ^ClojureLanguageServer server)
-              (.references (ReferenceParams. (TextDocumentIdentifier. uri)
-                                             (Position. line character)
-                                             (ReferenceContext. false)))
-              deref))))
+  (when-let [server (project->ls-server project)]
+    (some-> (.getTextDocumentService ^ClojureLanguageServer server)
+            (.references (ReferenceParams. (TextDocumentIdentifier. uri)
+                                           (Position. line character)
+                                           (ReferenceContext. false)))
+            deref)))
+
+(defn symbols [^String query ^Project project]
+  (when-let [server (project->ls-server project)]
+    (some-> (.getWorkspaceService ^ClojureLanguageServer server)
+            (.symbol (WorkspaceSymbolParams. query))
+            ^Either deref
+            .get)))
 
 (defn execute-command [^String name ^String text ^List args ^Project project]
   (try
@@ -54,4 +69,5 @@
         (.response)
         deref)
     (catch Exception e
-      (logger/error "Error appllying command" name (with-out-str (.printStackTrace e))))))
+      (logger/error (format "Error applying command '%s' with args '%s' for text '%s'" name args text)
+                    (with-out-str (.printStackTrace e))))))

src/main/clojure/com/github/clojure_lsp/intellij/extension/search_contributors.clj

@@ -0,0 +1,54 @@
+(ns com.github.clojure-lsp.intellij.extension.search-contributors
+  (:require
+   [com.github.clojure-lsp.intellij.client :as lsp-client]
+   [com.github.clojure-lsp.intellij.project-lsp :as project]
+   [com.github.ericdallo.clj4intellij.extension :refer [def-extension]]
+   [com.rpl.proxy-plus :refer [proxy+]])
+  (:import
+   [com.github.clojure_lsp.intellij Icons]
+   [com.intellij.ide.actions.searcheverywhere SearchEverywhereContributor SearchEverywhereContributorFactory]
+   [com.intellij.ide.util NavigationItemListCellRenderer]
+   [com.intellij.navigation ItemPresentation NavigationItem]
+   [com.intellij.openapi.actionSystem AnActionEvent]
+   [com.intellij.util Processor]
+   [com.redhat.devtools.lsp4ij.features.workspaceSymbol WorkspaceSymbolData]
+   [org.eclipse.lsp4j SymbolKind WorkspaceSymbol]))
+
+(set! *warn-on-reflection* true)
+
+(defn ^:private symbol->navigation-item ^NavigationItem
+  [^WorkspaceSymbol sym project]
+  (proxy+ [(.getName sym)
+           (.getKind sym)
+           (.getLeft (.getLocation sym))
+           (.getClientFeatures (lsp-client/project->ls-server-item project))
+           project]
+          WorkspaceSymbolData
+    (getPresentation [_]
+      (proxy+ [] ItemPresentation
+        (getPresentableText [_] (.getName sym))
+        (getIcon [_ _] Icons/CLOJURE)))))
+
+(def-extension NamespaceSearchContributorFactory []
+  SearchEverywhereContributorFactory
+  (isAvailable [_ project] (project/clojure-project? project))
+  (createContributor [_ ^AnActionEvent event]
+    (let [project (.getProject event)]
+      (proxy+ NamespaceSearchContributor []
+        SearchEverywhereContributor
+        (getSearchProviderId [_] "clojure-lsp-namespace-search")
+        (getGroupName [_] "Namespaces")
+        (getSortWeight [_] 301)
+        (showInFindResults [_] true)
+        (isShownInSeparateTab [_] true)
+        (isEmptyPatternSupported [_] true)
+        (fetchElements [_ pattern _indicator ^Processor consumer]
+          (let [syms (->> (lsp-client/symbols pattern project)
+                          (filter #(identical? SymbolKind/Namespace (.getKind ^WorkspaceSymbol %))))]
+            (doseq [sym syms]
+              (.process consumer (symbol->navigation-item sym project)))))
+        (processSelectedItem [_ ^NavigationItem item _modifiers _search-text]
+          (.navigate item true)
+          true)
+        (getElementsRenderer [_]
+          (NavigationItemListCellRenderer.))))))

src/main/resources/META-INF/plugin.xml

@@ -69,6 +69,7 @@
         <lang.quoteHandler language="clojure" implementationClass="com.github.clojure_lsp.intellij.extension.QuoteHandler"/>
         <lang.braceMatcher language="clojure" implementationClass="com.github.clojure_lsp.intellij.extension.brace_matcher.BraceMatcher"/>
         <applicationService serviceImplementation="com.github.clojure_lsp.intellij.extension.SettingsState"/>
+        <searchEverywhereContributor implementation="com.github.clojure_lsp.intellij.extension.search_contributors.NamespaceSearchContributorFactory"/>
         <applicationConfigurable
             parentId="tools"
             instance="com.github.clojure_lsp.intellij.extension.general_settings.ClojureGeneralSettingsConfigurable"