|
| 1 | +defmodule CircularBuffer do |
| 2 | + use GenServer |
| 3 | + |
| 4 | + @moduledoc """ |
| 5 | + An API to a stateful process that fills and empties a circular buffer |
| 6 | + """ |
| 7 | + |
| 8 | + # CLIENT API |
| 9 | + |
| 10 | + @doc """ |
| 11 | + Create a new buffer of a given capacity |
| 12 | + """ |
| 13 | + @spec new(capacity :: integer) :: {:ok, pid} |
| 14 | + def new(capacity) do |
| 15 | + GenServer.start_link(__MODULE__, capacity, []) |
| 16 | + end |
| 17 | + |
| 18 | + @doc """ |
| 19 | + Read the oldest entry in the buffer, fail if it is empty |
| 20 | + """ |
| 21 | + @spec read(buffer :: pid) :: {:ok, any} | {:error, atom} |
| 22 | + def read(buffer) do |
| 23 | + GenServer.call(buffer, :read) |
| 24 | + end |
| 25 | + |
| 26 | + @doc """ |
| 27 | + Write a new item in the buffer, fail if is full |
| 28 | + """ |
| 29 | + @spec write(buffer :: pid, item :: any) :: :ok | {:error, atom} |
| 30 | + def write(buffer, item) do |
| 31 | + GenServer.call(buffer, {:write, item}) |
| 32 | + end |
| 33 | + |
| 34 | + @doc """ |
| 35 | + Write an item in the buffer, overwrite the oldest entry if it is full |
| 36 | + """ |
| 37 | + @spec overwrite(buffer :: pid, item :: any) :: :ok |
| 38 | + def overwrite(buffer, item) do |
| 39 | + GenServer.cast(buffer, {:overwrite, item}) |
| 40 | + end |
| 41 | + |
| 42 | + @doc """ |
| 43 | + Clear the buffer |
| 44 | + """ |
| 45 | + @spec clear(buffer :: pid) :: :ok |
| 46 | + def clear(buffer) do |
| 47 | + GenServer.cast(buffer, :clear) |
| 48 | + end |
| 49 | + |
| 50 | + # DATA STRUCTURE |
| 51 | + # Essentially a deque made out of two lists, one for new input (write, overwrite) |
| 52 | + # and one for output (read), and keeping track of the size and capacity. |
| 53 | + |
| 54 | + defstruct [:capacity, size: 0, input: [], output: []] |
| 55 | + |
| 56 | + def new_buffer(capacity), do: {:ok, %CircularBuffer{capacity: capacity}} |
| 57 | + |
| 58 | + def read_buffer(%CircularBuffer{size: 0} = buffer), do: {{:error, :empty}, buffer} |
| 59 | + |
| 60 | + def read_buffer(%CircularBuffer{size: size, output: [out | output]} = buffer), |
| 61 | + do: {{:ok, out}, %{buffer | size: size - 1, output: output}} |
| 62 | + |
| 63 | + def read_buffer(%CircularBuffer{input: input} = buffer), |
| 64 | + do: read_buffer(%{buffer | input: [], output: Enum.reverse(input)}) |
| 65 | + |
| 66 | + def write_buffer(%CircularBuffer{size: capacity, capacity: capacity} = buffer, _item), |
| 67 | + do: {{:error, :full}, buffer} |
| 68 | + |
| 69 | + def write_buffer(%CircularBuffer{size: size, input: input} = buffer, item), |
| 70 | + do: {:ok, %{buffer | size: size + 1, input: [item | input]}} |
| 71 | + |
| 72 | + def overwrite_buffer(%CircularBuffer{size: capacity, capacity: capacity} = buffer, item) do |
| 73 | + {_, smaller_buffer} = read_buffer(buffer) |
| 74 | + write_buffer(smaller_buffer, item) |
| 75 | + end |
| 76 | + |
| 77 | + def overwrite_buffer(buffer, item), do: write_buffer(buffer, item) |
| 78 | + |
| 79 | + def clear_buffer(%CircularBuffer{capacity: capacity}), do: %CircularBuffer{capacity: capacity} |
| 80 | + |
| 81 | + @impl true |
| 82 | + def init(capacity) do |
| 83 | + new_buffer(capacity) |
| 84 | + end |
| 85 | + |
| 86 | + # SERVER API |
| 87 | + |
| 88 | + @impl true |
| 89 | + def handle_call(:read, _from, buffer) do |
| 90 | + {reply, buffer} = read_buffer(buffer) |
| 91 | + {:reply, reply, buffer} |
| 92 | + end |
| 93 | + |
| 94 | + @impl true |
| 95 | + def handle_call({:write, item}, _from, buffer) do |
| 96 | + {reply, buffer} = write_buffer(buffer, item) |
| 97 | + {:reply, reply, buffer} |
| 98 | + end |
| 99 | + |
| 100 | + @impl true |
| 101 | + def handle_cast({:overwrite, item}, buffer) do |
| 102 | + {_reply, buffer} = overwrite_buffer(buffer, item) |
| 103 | + {:noreply, buffer} |
| 104 | + end |
| 105 | + |
| 106 | + @impl true |
| 107 | + def handle_cast(:clear, buffer) do |
| 108 | + {:noreply, clear_buffer(buffer)} |
| 109 | + end |
| 110 | +end |
0 commit comments