Expose Structure.dump_cmd/3 (#423)

Author: maennchen

integration_test/myxql/storage_test.exs

@@ -159,4 +159,18 @@ defmodule Ecto.Integration.StorageTest do
     |> Enum.reject(&String.contains?(&1, "completed on"))
     |> Enum.join("\n")
   end
+
+  test "structure dump_cmd" do
+    num = @base_migration + System.unique_integer([:positive])
+    :ok = Ecto.Migrator.up(PoolRepo, num, Migration, log: false)
+
+    assert {output, 0} =
+             Ecto.Adapters.MyXQL.dump_cmd(
+               ["--no-create-info", "--tables", "schema_migrations"],
+               [],
+               PoolRepo.config()
+             )
+
+    assert output =~ "INSERT INTO `schema_migrations` VALUES ("
+  end
 end

integration_test/pg/storage_test.exs

@@ -165,4 +165,16 @@ defmodule Ecto.Integration.StorageTest do
              assert {:error, _} = Postgres.storage_status(wrong_params())
            end) =~ ~r"FATAL (28000|28P01)"
   end
+
+  test "structure dump_cmd" do
+    num = @base_migration + System.unique_integer([:positive])
+    :ok = Ecto.Migrator.up(PoolRepo, num, Migration, log: false)
+
+    assert {"--\n-- PostgreSQL database dump\n--\n\n--" <> _rest, 0} =
+             Postgres.dump_cmd(
+               ["--data-only", "--table", "schema_migrations"],
+               [],
+               PoolRepo.config()
+             )
+  end
 end

lib/ecto/adapter/structure.ex

@@ -38,4 +38,25 @@ defmodule Ecto.Adapter.Structure do
   """
   @callback structure_load(default :: String.t, config :: Keyword.t) ::
             {:ok, String.t} | {:error, term}
+
+  @doc """
+  Runs the dump command for the given repo / config.
+
+  Calling this function will setup authentication and run the dump cli
+  command with your provided `args`.
+
+  The options in `opts` are passed directly to `System.cmd/3`.
+
+  Returns `{output, exit_status}` where `output` is a string of the stdout
+  (as long as no option `into` is provided, see `System.cmd/3`) and `exit_status`
+  is the exit status of the invoation. (`0` for success)
+
+  ## Examples
+
+      iex> dump_cmd(["--data-only", "--table", "table_name"], [stdout_to_stderr: true], Acme.Repo.config())
+      "--\n-- PostgreSQL database dump\n--\n" <> _rest
+
+  """
+  @callback dump_cmd(args :: [String.t()], opts :: Keyword.t(), config :: Keyword.t()) ::
+              {output :: Collectable.t(), exit_status :: non_neg_integer()}
 end

lib/ecto/adapters/myxql.ex

@@ -344,17 +344,18 @@ defmodule Ecto.Adapters.MyXQL do
   def structure_load(default, config) do
     path = config[:dump_path] || Path.join(default, "structure.sql")
 
-    args = [
-      "--execute", "SET FOREIGN_KEY_CHECKS = 0; SOURCE #{path}; SET FOREIGN_KEY_CHECKS = 1",
-      "--database", config[:database]
-    ]
+    args = ["--execute", "SET FOREIGN_KEY_CHECKS = 0; SOURCE #{path}; SET FOREIGN_KEY_CHECKS = 1"]
 
     case run_with_cmd("mysql", config, args) do
       {_output, 0} -> {:ok, path}
       {output, _}  -> {:error, output}
     end
   end
 
+  @impl true
+  def dump_cmd(args, opts \\ [], config) when is_list(config) and is_list(args),
+    do: run_with_cmd("mysqldump", config, args, opts)
+
   ## Helpers
 
   defp run_query(sql, opts) do
@@ -395,7 +396,7 @@ defmodule Ecto.Adapters.MyXQL do
 
   defp exit_to_exception(reason), do: RuntimeError.exception(Exception.format_exit(reason))
 
-  defp run_with_cmd(cmd, opts, opt_args) do
+  defp run_with_cmd(cmd, opts, opt_args, cmd_opts \\ []) do
     unless System.find_executable(cmd) do
       raise "could not find executable `#{cmd}` in path, " <>
             "please guarantee it is available before running ecto commands"
@@ -419,13 +420,26 @@ defmodule Ecto.Adapters.MyXQL do
         []
       end
 
+    database_args =
+      if database = opts[:database] do
+        ["--database", database]
+      else
+        []
+      end
+
     args =
       [
         "--host", host,
         "--port", to_string(port),
         "--protocol", protocol
-      ] ++ user_args ++ opt_args
+      ] ++ user_args ++ database_args ++ opt_args
+
+    cmd_opts =
+      cmd_opts
+      |> Keyword.put_new(:stderr_to_stdout, true)
+      |> Keyword.update(:env, env, &Enum.concat(env, &1))
+
 
-    System.cmd(cmd, args, env: env, stderr_to_stdout: true)
+    System.cmd(cmd, args, cmd_opts)
   end
 end

lib/ecto/adapters/postgres.ex

@@ -267,8 +267,7 @@ defmodule Ecto.Adapters.Postgres do
     path = config[:dump_path] || Path.join(default, "structure.sql")
     File.mkdir_p!(Path.dirname(path))
 
-    case run_with_cmd("pg_dump", config, ["--file", path, "--schema-only", "--no-acl",
-                                          "--no-owner", config[:database]]) do
+    case run_with_cmd("pg_dump", config, ["--file", path, "--schema-only", "--no-acl", "--no-owner"]) do
       {_output, 0} ->
         {:ok, path}
       {output, _} ->
@@ -293,14 +292,17 @@ defmodule Ecto.Adapters.Postgres do
   @impl true
   def structure_load(default, config) do
     path = config[:dump_path] || Path.join(default, "structure.sql")
-    args = ["--quiet", "--file", path, "-vON_ERROR_STOP=1",
-            "--single-transaction", config[:database]]
+    args = ["--quiet", "--file", path, "-vON_ERROR_STOP=1", "--single-transaction"]
     case run_with_cmd("psql", config, args) do
       {_output, 0} -> {:ok, path}
       {output, _}  -> {:error, output}
     end
   end
 
+  @impl true
+  def dump_cmd(args, opts \\ [], config) when is_list(config) and is_list(args),
+    do: run_with_cmd("pg_dump", config, args, opts)
+
   ## Helpers
 
   defp run_query(sql, opts) do
@@ -338,7 +340,7 @@ defmodule Ecto.Adapters.Postgres do
     end
   end
 
-  defp run_with_cmd(cmd, opts, opt_args) do
+  defp run_with_cmd(cmd, opts, opt_args, cmd_opts \\ []) do
     unless System.find_executable(cmd) do
       raise "could not find executable `#{cmd}` in path, " <>
             "please guarantee it is available before running ecto commands"
@@ -356,9 +358,11 @@ defmodule Ecto.Adapters.Postgres do
     args =
       []
     args =
-      if username = opts[:username], do: ["-U", username|args], else: args
+      if username = opts[:username], do: ["--username", username | args], else: args
+    args =
+      if port = opts[:port], do: ["--port", to_string(port) | args], else: args
     args =
-      if port = opts[:port], do: ["-p", to_string(port)|args], else: args
+      if database = opts[:database], do: ["--dbname", database | args], else: args
 
     host = opts[:socket_dir] || opts[:hostname] || System.get_env("PGHOST") || "localhost"
 
@@ -369,8 +373,14 @@ defmodule Ecto.Adapters.Postgres do
       )
     end
 
-    args = ["--host", host|args]
+    args = ["--host", host | args]
     args = args ++ opt_args
-    System.cmd(cmd, args, env: env, stderr_to_stdout: true)
+
+    cmd_opts =
+      cmd_opts
+      |> Keyword.put_new(:stderr_to_stdout, true)
+      |> Keyword.update(:env, env, &Enum.concat(env, &1))
+
+    System.cmd(cmd, args, cmd_opts)
   end
 end

test/mix/tasks/ecto.dump_load_test.exs

@@ -23,6 +23,7 @@ defmodule Mix.Tasks.Ecto.DumpLoadTest do
 
     def structure_dump(_, _), do: Process.get(:structure_dump) || raise "no structure_dump"
     def structure_load(_, _), do: Process.get(:structure_load) || raise "no structure_load"
+    def dump_cmd(_, _, _), do: Process.get(:dump_cmd) || raise "no dump_cmd"
   end
 
   defmodule NoStructureAdapter do