added server.accept()

Author: JAndrassy

examples/WiFiAdvancedChatServer/WiFiAdvancedChatServer.ino

@@ -0,0 +1,117 @@
+/*
+ Advanced WiFi Chat Server
+
+ A more advanced server that distributes any incoming messages
+ to all connected clients but the client the message comes from.
+ To use, telnet to your device's IP address and type.
+ You can see the client's input in the serial monitor as well.
+
+ Circuit:
+  * Board with NINA module (Arduino MKR WiFi 1010, MKR VIDOR 4000 and UNO WiFi Rev.2)
+
+ created 18 Dec 2009
+ by David A. Mellis
+ modified 9 Apr 2012
+ by Tom Igoe
+ redesigned to make use of operator== 25 Nov 2013
+ by Norbert Truchsess
+ changed for server.accept() in July 2018
+ by Paul Stoffregen for Ethernet library
+
+ */
+
+#include <SPI.h>
+#include <WiFiNINA.h>
+
+#include "arduino_secrets.h"
+///////please enter your sensitive data in the Secret tab/arduino_secrets.h
+char ssid[] = SECRET_SSID;        // your network SSID (name)
+char pass[] = SECRET_PASS;    // your network password (use for WPA, or use as key for WEP)
+
+int status = WL_IDLE_STATUS;
+
+// telnet defaults to port 23
+WiFiServer server(23);
+
+WiFiClient clients[8];
+
+void setup() {
+  //Initialize serial and wait for port to open:
+  Serial.begin(9600);
+  while (!Serial) {
+    ; // wait for serial port to connect. Needed for native USB port only
+  }
+
+  // check for the WiFi module:
+  if (WiFi.status() == WL_NO_MODULE) {
+    Serial.println("Communication with WiFi module failed!");
+    // don't continue
+    while (true);
+  }
+
+  String fv = WiFi.firmwareVersion();
+  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
+    Serial.println("Please upgrade the firmware");
+  }
+
+  // attempt to connect to WiFi network:
+  while (status != WL_CONNECTED) {
+    Serial.print("Attempting to connect to SSID: ");
+    Serial.println(ssid);
+    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
+    status = WiFi.begin(ssid, pass);
+
+    // wait 10 seconds for connection:
+    delay(10000);
+  }
+
+  // start the server:
+  server.begin();
+
+  Serial.print("Chat server address:");
+  Serial.println(WiFi.localIP());
+}
+
+void loop() {
+  // check for any new client connecting, and say hello (before any incoming data)
+  WiFiClient newClient = server.accept();
+  if (newClient) {
+    for (byte i=0; i < 8; i++) {
+      if (!clients[i]) {
+        Serial.print("We have a new client #");
+        Serial.println(i);
+        newClient.print("Hello, client number: ");
+        newClient.println(i);
+        // Once we "accept", the client is no longer tracked by EthernetServer
+        // so we must store it into our list of clients
+        clients[i] = newClient;
+        break;
+      }
+    }
+  }
+
+  // check for incoming data from all clients
+  for (byte i=0; i < 8; i++) {
+    if (clients[i] && clients[i].available() > 0) {
+      // read bytes from a client
+      byte buffer[80];
+      int count = clients[i].read(buffer, 80);
+      // write the bytes to all other connected clients
+      for (byte j=0; j < 8; j++) {
+        if (j != i && clients[j].connected()) {
+          clients[j].write(buffer, count);
+        }
+      }
+    }
+  }
+
+  // stop any clients which disconnect
+  for (byte i=0; i < 8; i++) {
+    if (clients[i] && !clients[i].connected()) {
+      Serial.print("disconnect client #");
+      Serial.println(i);
+      clients[i].stop();
+    }
+  }
+
+}

examples/WiFiAdvancedChatServer/arduino_secrets.h

@@ -0,0 +1,2 @@
+#define SECRET_SSID ""
+#define SECRET_PASS ""

src/WiFiServer.cpp

@@ -80,6 +80,12 @@ WiFiClient WiFiServer::available(byte* status)
     return WiFiClient(255);
 }
 
+WiFiClient WiFiServer::accept()
+{
+    int sock = ServerDrv::availServer(_sock, true);
+    return WiFiClient(sock);
+}
+
 uint8_t WiFiServer::status() {
     if (_sock == NO_SOCKET_AVAIL) {
         return CLOSED;

src/WiFiServer.h

@@ -38,6 +38,7 @@ class WiFiServer : public Server {
 public:
   WiFiServer(uint16_t);
   WiFiClient available(uint8_t* status = NULL);
+  WiFiClient accept();
   void begin();
   virtual size_t write(uint8_t);
   virtual size_t write(const uint8_t *buf, size_t size);

src/utility/server_drv.cpp

@@ -256,16 +256,17 @@ uint16_t ServerDrv::availData(uint8_t sock)
     return len;
 }
 
-uint8_t ServerDrv::availServer(uint8_t sock)
+uint8_t ServerDrv::availServer(uint8_t sock, uint8_t accept)
 {
     if (!SpiDrv::available()) {
         return 255;
     }
 
     WAIT_FOR_SLAVE_SELECT();
     // Send Command
-    SpiDrv::sendCmd(AVAIL_DATA_TCP_CMD, PARAM_NUMS_1);
-    SpiDrv::sendParam(&sock, sizeof(sock), LAST_PARAM);
+    SpiDrv::sendCmd(AVAIL_DATA_TCP_CMD, PARAM_NUMS_2);
+    SpiDrv::sendParam(&sock, sizeof(sock));
+    SpiDrv::sendParam(&accept, sizeof(accept), LAST_PARAM);
 
     // pad to multiple of 4
     SpiDrv::readChar();

src/utility/server_drv.h

@@ -57,7 +57,7 @@ class ServerDrv
 
     static uint16_t availData(uint8_t sock);
 
-    static uint8_t availServer(uint8_t sock);
+    static uint8_t availServer(uint8_t sock, uint8_t accept = false);
 
     static uint8_t checkDataSent(uint8_t sock);