SourceKit: remove LINK_LIBS (NFC)

This removes the custom `LINK_LIBS` in favour of
`target_link_libraries`.  This simplifies the custom functions that we
have for adding libraries, makes it easier to query the information from
ninja and will allow us to slowly remove more of the custom logic for
building the products.

Author: compnerd

tools/SourceKit/cmake/modules/AddSwiftSourceKit.cmake

@@ -87,7 +87,6 @@ endfunction()
 #
 # Usage:
 #   add_sourcekit_library(name     # Name of the library
-#     [LINK_LIBS dep1 ...]         # Libraries this library will be linked with
 #     [DEPENDS dep1 ...]           # Targets this library depends on
 #     [LLVM_LINK_COMPONENTS comp1 ...]  # LLVM components this library depends on
 #     [INSTALL_IN_COMPONENT comp]  # The Swift installation component that this library belongs to.
@@ -97,7 +96,7 @@ macro(add_sourcekit_library name)
   cmake_parse_arguments(SOURCEKITLIB
       "SHARED"
       "INSTALL_IN_COMPONENT"
-      "HEADERS;LINK_LIBS;DEPENDS;LLVM_LINK_COMPONENTS"
+      "HEADERS;DEPENDS;LLVM_LINK_COMPONENTS"
       ${ARGN})
   set(srcs ${SOURCEKITLIB_UNPARSED_ARGUMENTS})
 
@@ -149,21 +148,6 @@ macro(add_sourcekit_library name)
     add_dependencies(${name} ${SOURCEKITLIB_DEPENDS})
   endif(SOURCEKITLIB_DEPENDS)
 
-  set(prefixed_link_libraries)
-  foreach(dep ${SOURCEKITLIB_LINK_LIBS})
-    if("${dep}" MATCHES "^clang")
-      set(dep "${LLVM_LIBRARY_OUTPUT_INTDIR}/${CMAKE_STATIC_LIBRARY_PREFIX}${dep}${CMAKE_STATIC_LIBRARY_SUFFIX}")
-    endif()
-    list(APPEND prefixed_link_libraries "${dep}")
-  endforeach()
-  set(SOURCEKITLIB_LINK_LIBS "${prefixed_link_libraries}")
-
-  if("${libkind}" STREQUAL "SHARED")
-    target_link_libraries("${name}" PRIVATE ${SOURCEKITLIB_LINK_LIBS})
-  else()
-    target_link_libraries("${name}" INTERFACE ${SOURCEKITLIB_LINK_LIBS})
-  endif()
-
   swift_common_llvm_config(${name} ${SOURCEKITLIB_LLVM_LINK_COMPONENTS})
 
   if(SOURCEKITLIB_SHARED AND EXPORTED_SYMBOL_FILE)
@@ -213,7 +197,6 @@ endmacro()
 #
 # Usage:
 #   add_sourcekit_executable(name        # Name of the executable
-#     [LINK_LIBS dep1 ...]               # Libraries this executable depends on
 #     [LLVM_LINK_COMPONENTS comp1 ...] # LLVM components this executable
 #                                        # depends on
 #     [EXCLUDE_FROM_ALL]              # Whether to exclude this executable from
@@ -223,7 +206,7 @@ macro(add_sourcekit_executable name)
   cmake_parse_arguments(SOURCEKITEXE
     "EXCLUDE_FROM_ALL"
     ""
-    "LINK_LIBS;LLVM_LINK_COMPONENTS"
+    "LLVM_LINK_COMPONENTS"
     ${ARGN})
 
   if (${SOURCEKITEXE_EXCLUDE_FROM_ALL})
@@ -244,7 +227,6 @@ macro(add_sourcekit_executable name)
     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
   endif()
 
-  target_link_libraries(${name} PRIVATE ${SOURCEKITEXE_LINK_LIBS})
   swift_common_llvm_config(${name} ${SOURCEKITEXE_LLVM_LINK_COMPONENTS})
   target_link_libraries(${name} PRIVATE ${LLVM_COMMON_LIBS})
 
@@ -267,14 +249,13 @@ endmacro()
 #
 # Usage:
 #   add_sourcekit_framework(name     # Name of the framework
-#     [LINK_LIBS dep1 ...]           # Libraries this framework will link with
 #     [LLVM_LINK_COMPONENTS comp1 ...]  # LLVM components this framework depends on
 #     [MODULEMAP modulemap]          # Module map file for this framework
 #     [INSTALL_IN_COMPONENT comp]    # The Swift installation component that this framework belongs to.
 #     source1 [source2 source3 ...]) # Sources to add into this framework
 macro(add_sourcekit_framework name)
   cmake_parse_arguments(SOURCEKITFW
-    "" "MODULEMAP;INSTALL_IN_COMPONENT" "LINK_LIBS;LLVM_LINK_COMPONENTS" ${ARGN})
+    "" "MODULEMAP;INSTALL_IN_COMPONENT" "LLVM_LINK_COMPONENTS" ${ARGN})
   set(srcs ${SOURCEKITFW_UNPARSED_ARGUMENTS})
 
   set(lib_dir ${SOURCEKIT_LIBRARY_OUTPUT_INTDIR})
@@ -316,7 +297,6 @@ macro(add_sourcekit_framework name)
     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
   endif(LLVM_COMMON_DEPENDS)
 
-  target_link_libraries(${name} PRIVATE ${SOURCEKITFW_LINK_LIBS})
   swift_common_llvm_config(${name} ${SOURCEKITFW_LLVM_LINK_COMPONENTS})
 
   if (EXPORTED_SYMBOL_FILE)
@@ -394,11 +374,10 @@ endmacro(add_sourcekit_framework)
 #
 # Usage:
 #   add_sourcekit_xpc_service(name      # Name of the XPC service
-#     [LINK_LIBS dep1 ...]              # Libraries this service will link with
 #     [LLVM_LINK_COMPONENTS comp1 ...]   # LLVM components this service depends on
 #     source1 [source2 source3 ...])    # Sources to add into this service
 macro(add_sourcekit_xpc_service name framework_target)
-  cmake_parse_arguments(SOURCEKITXPC "" "" "LINK_LIBS;LLVM_LINK_COMPONENTS" ${ARGN})
+  cmake_parse_arguments(SOURCEKITXPC "" "" "LLVM_LINK_COMPONENTS" ${ARGN})
   set(srcs ${SOURCEKITXPC_UNPARSED_ARGUMENTS})
 
   set(lib_dir ${SOURCEKIT_LIBRARY_OUTPUT_INTDIR})
@@ -439,7 +418,6 @@ macro(add_sourcekit_xpc_service name framework_target)
     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
   endif(LLVM_COMMON_DEPENDS)
 
-  target_link_libraries(${name} PRIVATE ${SOURCEKITXPC_LINK_LIBS})
   swift_common_llvm_config(${name} ${SOURCEKITXPC_LLVM_LINK_COMPONENTS})
   target_link_libraries(${name} PRIVATE ${LLVM_COMMON_LIBS})
 

tools/SourceKit/lib/Core/CMakeLists.txt

@@ -3,5 +3,6 @@ add_sourcekit_library(SourceKitCore
   Context.cpp
   LangSupport.cpp
   NotificationCenter.cpp
-  LINK_LIBS SourceKitSupport
 )
+target_link_libraries(SourceKitCore PRIVATE
+  SourceKitSupport)

tools/SourceKit/lib/Support/CMakeLists.txt

@@ -5,9 +5,12 @@ add_sourcekit_library(SourceKitSupport
   ImmutableTextBuffer.cpp
   ThreadSafeRefCntPtr.cpp
   Tracing.cpp
-  UIDRegistry.cpp
-  LINK_LIBS swiftBasic swiftSyntax clangBasic clangRewrite
-)
+  UIDRegistry.cpp)
+target_link_libraries(SourceKitSupport PRIVATE
+  swiftBasic
+  swiftSyntax
+  clangBasic
+  clangRewrite)
 if(SWIFT_NEED_EXPLICIT_LIBDISPATCH)
   target_link_libraries(SourceKitSupport INTERFACE dispatch BlocksRuntime)
 endif()

tools/SourceKit/lib/SwiftLang/CMakeLists.txt

@@ -10,31 +10,6 @@ add_sourcekit_library(SourceKitSwiftLang
   SwiftLangSupport.cpp
   SwiftSourceDocInfo.cpp
   SwiftTypeContextInfo.cpp
-  LINK_LIBS
-    SourceKitCore swiftDriver swiftFrontend
-    swiftClangImporter swiftIDE
-    swiftAST swiftMarkup swiftParse swiftParseSIL swiftSIL swiftSILGen
-    swiftSILOptimizer swiftIRGen swiftSema swiftBasic swiftSerialization
-    swiftSyntax swiftOption libcmark_static
-    # Clang dependencies.
-      clangIndex
-      clangFormat
-      clangToolingCore
-      clangFrontendTool
-      clangFrontend
-      clangDriver
-      clangCodeGen
-      clangSerialization
-      clangParse
-      clangSema
-      clangAnalysis
-      clangEdit
-      clangRewriteFrontend
-      clangRewrite
-      clangLex
-      clangAST
-      clangAPINotes
-      clangBasic
     LLVM_LINK_COMPONENTS ${LLVM_TARGETS_TO_BUILD}
       bitreader
       bitwriter
@@ -49,5 +24,43 @@ add_sourcekit_library(SourceKitSwiftLang
       objcarcopts
       profiledata
 )
-
+target_link_libraries(SourceKitSwiftLang PRIVATE
+  SourceKitCore
+  swiftDriver
+  swiftFrontend
+  swiftClangImporter
+  swiftIDE
+  swiftAST
+  swiftMarkup
+  swiftParse
+  swiftParseSIL
+  swiftSIL
+  swiftSILGen
+  swiftSILOptimizer
+  swiftIRGen
+  swiftSema
+  swiftBasic
+  swiftSerialization
+  swiftSyntax
+  swiftOption
+  libcmark_static
+  # Clang dependencies.
+  clangIndex
+  clangFormat
+  clangToolingCore
+  clangFrontendTool
+  clangFrontend
+  clangDriver
+  clangCodeGen
+  clangSerialization
+  clangParse
+  clangSema
+  clangAnalysis
+  clangEdit
+  clangRewriteFrontend
+  clangRewrite
+  clangLex
+  clangAST
+  clangAPINotes
+  clangBasic)
 add_dependencies(SourceKitSwiftLang clang-tablegen-targets)

tools/SourceKit/tools/complete-test/CMakeLists.txt

@@ -1,14 +1,12 @@
-if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
-  set(SOURCEKITD_TEST_LINK_LIBS sourcekitdInProc)
-else()
-  set(SOURCEKITD_TEST_LINK_LIBS sourcekitd)
-endif()
-
 add_sourcekit_executable(complete-test
   complete-test.cpp
-  LINK_LIBS ${SOURCEKITD_TEST_LINK_LIBS}
-  LLVM_LINK_COMPONENTS support option coverage lto
+  LLVM_LINK_COMPONENTS option coverage lto
 )
+if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
+  target_link_libraries(complete-test PRIVATE sourcekitdInProc)
+else()
+  target_link_libraries(complete-test PRIVATE sourcekitd)
+endif()
 if(SWIFT_NEED_EXPLICIT_LIBDISPATCH)
   target_link_libraries(complete-test PRIVATE dispatch BlocksRuntime)
 endif()

tools/SourceKit/tools/sourcekitd-repl/CMakeLists.txt

@@ -2,17 +2,16 @@ set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} edit)
 check_symbol_exists(el_wgets "histedit.h" HAVE_UNICODE_LIBEDIT)
 
 if(HAVE_UNICODE_LIBEDIT)
-  if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
-    set(SOURCEKITD_REPL_LINK_LIBS sourcekitdInProc)
-  else()
-    set(SOURCEKITD_REPL_LINK_LIBS sourcekitd)
-  endif()
-
   add_sourcekit_executable(sourcekitd-repl
     sourcekitd-repl.cpp
-    LINK_LIBS ${SOURCEKITD_REPL_LINK_LIBS} edit
-    LLVM_LINK_COMPONENTS support coverage lto
+    LLVM_LINK_COMPONENTS coverage lto
   )
+  target_link_libraries(sourcekitd-repl PRIVATE edit)
+  if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
+    target_link_libraries(sourcekitd-repl PRIVATE sourcekitdInProc)
+  else()
+    target_link_libraries(sourcekitd-repl PRIVATE sourcekitd)
+  endif()
   if(SWIFT_NEED_EXPLICIT_LIBDISPATCH)
     target_link_libraries(sourcekitd-repl PRIVATE dispatch BlocksRuntime)
   endif()

tools/SourceKit/tools/sourcekitd-test/CMakeLists.txt

@@ -2,19 +2,21 @@ set(LLVM_TARGET_DEFINITIONS Options.td)
 swift_tablegen(Options.inc -gen-opt-parser-defs)
 swift_add_public_tablegen_target(sourcekitdTestOptionsTableGen)
 
-if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
-  set(SOURCEKITD_TEST_LINK_LIBS sourcekitdInProc)
-else()
-  set(SOURCEKITD_TEST_LINK_LIBS sourcekitd)
-endif()
-
 add_sourcekit_executable(sourcekitd-test
   sourcekitd-test.cpp
   TestOptions.cpp
-  LINK_LIBS ${SOURCEKITD_TEST_LINK_LIBS} SourceKitSupport
-    clangRewrite clangLex clangBasic
-  LLVM_LINK_COMPONENTS core support option coverage lto
+  LLVM_LINK_COMPONENTS core option coverage lto
 )
+target_link_libraries(sourcekitd-test PRIVATE
+  SourceKitSupport
+  clangRewrite
+  clangLex
+  clangBasic)
+if(SWIFT_SOURCEKIT_USE_INPROC_LIBRARY)
+  target_link_libraries(sourcekitd-test PRIVATE sourcekitdInProc)
+else()
+  target_link_libraries(sourcekitd-test PRIVATE sourcekitd)
+endif()
 if(SWIFT_NEED_EXPLICIT_LIBDISPATCH)
   target_link_libraries(sourcekitd-test PRIVATE dispatch BlocksRuntime)
 endif()

tools/SourceKit/tools/sourcekitd/bin/InProc/CMakeLists.txt

@@ -5,7 +5,6 @@ option(SOURCEKITD_BUILD_STATIC_INPROC
 
 set(sourcekitdInProc_args
   sourcekitdInProc.cpp
-  LINK_LIBS SourceKitSwiftLang sourcekitdAPI
   LLVM_LINK_COMPONENTS support coverage
 )
 
@@ -36,6 +35,9 @@ else()
     SHARED
   )
 endif()
+target_link_libraries(sourcekitdInProc PRIVATE
+  SourceKitSwiftLang
+  sourcekitdAPI)
 
 # While it is possible to build this as a static library,
 # to get the runtime paths correct, it must be linked into a binary
@@ -46,6 +48,9 @@ if (SOURCEKITD_BUILD_STATIC_INPROC)
       ${SOURCEKITD_SOURCE_DIR}/include/sourcekitd/sourcekitd.h
     ${sourcekitdInProc_args}
   )
+  target_link_libraries(sourcekitdInProc_Static PRIVATE
+    SourceKitSwiftLang
+    sourcekitdAPI)
 endif()
 
 if (SOURCEKIT_BUILT_STANDALONE)

tools/SourceKit/tools/sourcekitd/bin/XPC/Client/CMakeLists.txt

@@ -10,11 +10,11 @@ set(EXPORTED_SYMBOL_FILE "${SOURCEKITD_SOURCE_DIR}/bin/sourcekitd.exports")
 add_sourcekit_framework(sourcekitd
   ${public_headers}
   sourcekitd.cpp
-  LINK_LIBS sourcekitdAPI
   LLVM_LINK_COMPONENTS support
   MODULEMAP module.modulemap
   INSTALL_IN_COMPONENT sourcekit-xpc-service
 )
+target_link_libraries(sourcekitd PRIVATE sourcekitdAPI)
 
 add_definitions(-DSOURCEKIT_XPCSERVICE_IDENTIFIER="com.apple.SourceKitService.${SOURCEKIT_VERSION_STRING}_${SOURCEKIT_PLATFORM_NAME}")
 

tools/SourceKit/tools/sourcekitd/bin/XPC/Service/CMakeLists.txt

@@ -1,9 +1,11 @@
 if (NOT SOURCEKIT_INSTALLING_INPROC)
   add_sourcekit_xpc_service(SourceKitService sourcekitd
     XPCService.cpp
-    LINK_LIBS SourceKitSwiftLang sourcekitdAPI
     LLVM_LINK_COMPONENTS support coverage
   )
+  target_link_libraries(SourceKitService PRIVATE
+    SourceKitSwiftLang
+    sourcekitdAPI)
 endif()
 
 if (NOT SOURCEKIT_DEPLOYMENT_OS MATCHES "^macosx")